add 'mailman3'

21 files changed, 667 insertions, 0 deletions

diff --git a/pcr-testing/django-allauth/PKGBUILD b/pcr-testing/django-allauth/PKGBUILD
new file mode 100644
index 000000000..cd931df53
--- /dev/null
+++ b/pcr-testing/django-allauth/PKGBUILD
@@ -0,0 +1,42 @@
+# Maintainer: bill-auger <bill-auger@programmer.net>
+# Maintainer (AUR): Simon Hanna <simon dot hanna AT serve-me DOT info>
+# Contributor: Jakob Gahde <j5lx@fmail.co.uk>
+
+pkgbase='django-allauth'
+pkgname=('python-django-allauth' 'python2-django-allauth')
+pkgver=0.37.0
+pkgrel=1
+pkgdesc="Integrated set of Django applications addressing authentication, registration, account management as well as 3rd party (social) account authentication."
+arch=('any')
+license=('MIT')
+url=http://www.intenct.nl/projects/django-allauth/
+
+makedepends=('python-setuptools' 'python2-setuptools')
+
+source=(https://github.com/pennersr/${pkgbase}/archive/${pkgver}.tar.gz)
+sha256sums=('3d526573d0f3463506c605224a9bb444cdf0ad2e7118206a8e8cf9af6489efc3')
+
+
+package_python-django-allauth()
+{
+  depends=('python' 'python-django>=1.11' 'python2-openid' 'python-requests-oauthlib>=0.3.0'
+           'python-requests')
+
+  cd "${srcdir}/${pkgbase}-${pkgver}"
+
+  python setup.py install --root="${pkgdir}" -O1
+
+  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_python2-django-allauth()
+{
+  depends=('python2' 'python2-django>=1.10' 'python2-openid'
+           'python2-requests-oauthlib' 'python2-requests')
+
+  cd "${srcdir}/${pkgbase}-${pkgver}"
+
+  python2 setup.py install --root="${pkgdir}" -O1
+
+  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
diff --git a/pcr-testing/django-gravatar/PKGBUILD b/pcr-testing/django-gravatar/PKGBUILD
new file mode 100644
index 000000000..37d0a59e3
--- /dev/null
+++ b/pcr-testing/django-gravatar/PKGBUILD
@@ -0,0 +1,40 @@
+# Maintainer: bill-auger <bill-auger@programmer.net>
+# Maintainer (AUR): Simon Hanna <simon dot hanna AT serve-me DOT info>
+
+pkgbase='django-gravatar'
+pkgname=('python-django-gravatar' 'python2-django-gravatar')
+pkgver=1.4.2
+pkgrel=1
+pkgdesc="Includes helper methods for interacting with gravatars outside of template code"
+arch=(any)
+url=https://github.com/twaddington/django-gravatar
+license=('MIT')
+options=(!emptydirs)
+
+makedepends=('python-setuptools' 'python2-setuptools')
+
+source=(https://github.com/twaddington/${pkgbase}/archive/${pkgver}.tar.gz)
+sha256sums=('ee2a1e62ca894352a349c104997bc1d7452461ca4fc6d24e97cc5937315740e1')
+
+
+package_python-django-gravatar()
+{
+  depends=('python-django')
+
+  cd "${srcdir}/${pkgbase}-${pkgver}"
+
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+
+  python setup.py install --root="$pkgdir/" --optimize=1
+}
+
+package_python2-django-gravatar()
+{
+  depends=('python2-django')
+
+  cd "${srcdir}/${pkgbase}-${pkgver}"
+
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+}
diff --git a/pcr-testing/mailman-core/PKGBUILD b/pcr-testing/mailman-core/PKGBUILD
new file mode 100644
index 000000000..3d28523e9
--- /dev/null
+++ b/pcr-testing/mailman-core/PKGBUILD
@@ -0,0 +1,49 @@
+# Maintainer: bill-auger <bill-auger@programmer.net>
+# Maintainer (AUR): Simon Hanna <simon dot hanna AT serve-me DOT info>
+
+pkgname=('mailman-core')
+pkgver=3.2.0
+pkgrel=1
+pkgdesc="A mailing list management system"
+arch=(any)
+conflicts=('mailman')
+url=https://gitlab.com/mailman/mailman
+license=('LGPL')
+options=(!emptydirs)
+
+makedepends=('python-setuptools')
+depends=('python-zope-interface' 'python-zope-event' 'python-zope-configuration'
+         'python-zope-component' 'python-passlib' 'python-click' 'python-flufl-lock'
+         'python-flufl-i18n' 'python-flufl-bounce' 'python-falcon' 'python-alembic'
+         'python-lazr-config' 'python-lazr-smtptest' 'python-aiosmtpd' 'python-atpublic'
+         'python-dnspython' 'python-requests' 'postfix')
+optdepends=('python-mailman-hyperkitty-plugin: Plugin to send emails to the Hyperkitty archiver')
+
+install=${pkgname}.install
+backup=('var/lib/mailman/var/etc/mailman.cfg')
+_upstream_name='mailman'
+_release="${_upstream_name}-${pkgver}"
+source=(https://gitlab.com/mailman/${_upstream_name}/-/archive/${pkgver}/${_release}.tar.gz
+        'mailman.sysusers'
+        'mailman.service'
+        'mailman.cfg')
+sha256sums=('17b9765b75e13b933df27aff01d634bd2ab6574bd4ee3b248b4f9ee9ed8dffc4'
+            'a99bf88267184fee0568856ac09bb682224ee67029cfc20f603a43fe5f053dad'
+            '81048cb6a27490fb36881b2eb88567b2ea2271b481dd0254fe9a398e6ca9beaf'
+            'f48dac59786be58c6a8b5fe2a12f4f356872d87600be64506f22066508847f3a')
+
+
+package()
+{
+  cd "$srcdir/${_release}"
+
+  # install systemd files
+  install -Dm 644 "${srcdir}/mailman.service" "${pkgdir}/usr/lib/systemd/system/mailman.service"
+  install -Dm 644 "${srcdir}/mailman.sysusers" "${pkgdir}/usr/lib/sysusers.d/mailman.conf"
+
+  # copy configuration file and create symlink in /etc
+  install -dm 770 "${pkgdir}/var/lib/mailman"
+  install -Dm 644 "${srcdir}/mailman.cfg" "${pkgdir}/var/lib/mailman/var/etc/mailman.cfg"
+
+  python setup.py install --root="${pkgdir}/" --optimize=1
+}
diff --git a/pcr-testing/mailman-core/mailman-core.install b/pcr-testing/mailman-core/mailman-core.install
new file mode 100644
index 000000000..c4a4572ea
--- /dev/null
+++ b/pcr-testing/mailman-core/mailman-core.install
@@ -0,0 +1,11 @@
+#!/bin/sh
+
+post_install() {
+  # ensure correct permissions
+  systemd-sysusers mailman.conf
+  chown -R mailman:mailman /var/lib/mailman
+}
+
+post_remove() {
+  userdel mailman
+}
diff --git a/pcr-testing/mailman-core/mailman.cfg b/pcr-testing/mailman-core/mailman.cfg
new file mode 100644
index 000000000..f27c00007
--- /dev/null
+++ b/pcr-testing/mailman-core/mailman.cfg
@@ -0,0 +1,11 @@
+# This is your GNU Mailman 3 configuration file.  You can edit this file to
+# configure Mailman to your needs, and Mailman will never overwrite it.
+# Additional configuration information is (for now) available in the
+# schema.cfg file <http://tinyurl.com/cm5rtqe> and the base mailman.cfg file
+# <http://tinyurl.com/dx9b8eg>.
+#
+# For example, uncomment the following lines to run Mailman in developer mode.
+#
+# [devmode]
+# enabled: yes
+# recipient: your.address@your.domain
diff --git a/pcr-testing/mailman-core/mailman.service b/pcr-testing/mailman-core/mailman.service
new file mode 100644
index 000000000..5c852a22e
--- /dev/null
+++ b/pcr-testing/mailman-core/mailman.service
@@ -0,0 +1,16 @@
+[Unit]
+Description=GNU Mailing List Manager
+After=network.target
+
+[Service]
+User=mailman
+ExecStart=/usr/bin/mailman start -f
+ExecReload=/usr/bin/mailman restart
+ExecStop=/usr/bin/mailman stop
+StandardError=syslog
+Type=forking
+WorkingDirectory=/var/lib/mailman
+PIDFile=/var/lib/mailman/var/master.pid
+
+[Install]
+WantedBy=multi-user.target
diff --git a/pcr-testing/mailman-core/mailman.sysusers b/pcr-testing/mailman-core/mailman.sysusers
new file mode 100644
index 000000000..4df9b61f3
--- /dev/null
+++ b/pcr-testing/mailman-core/mailman.sysusers
@@ -0,0 +1 @@
+u mailman - "GNU Mailing List Manager" /var/lib/mailman
diff --git a/pcr-testing/python-aiosmtpd/PKGBUILD b/pcr-testing/python-aiosmtpd/PKGBUILD
new file mode 100644
index 000000000..3bb976dd2
--- /dev/null
+++ b/pcr-testing/python-aiosmtpd/PKGBUILD
@@ -0,0 +1,28 @@
+# Maintainer: bill-auger <bill-auger@programmer.net>
+# Maintainer (AUR): Simon Hanna <simon dot hanna AT serve-me DOT info>
+
+
+pkgname=('python-aiosmtpd')
+pkgver=1.1
+pkgrel=1
+pkgdesc="A reimplementation of the Python stdlib smtpd.py based on asyncio"
+arch=(any)
+url=https://github.com/aio-libs/aiosmtpd
+license=('Apache')
+options=(!emptydirs)
+
+makedepends=('python-setuptools')
+depends=('python-atpublic')
+
+_upstream_name='aiosmtpd'
+_release=${_upstream_name}-${pkgver}
+source=(https://github.com/aio-libs/aiosmtpd/archive/${pkgver}.tar.gz)
+sha256sums=('5a3925a0c7609005e5cfd96e916a644e20b201b6743ffe0e095addb2b146a198')
+
+
+package()
+{
+  cd "${srcdir}/${_release}"
+
+  python setup.py install --root="${pkgdir}/" --optimize=1
+}
diff --git a/pcr-testing/python-atpublic/PKGBUILD b/pcr-testing/python-atpublic/PKGBUILD
new file mode 100644
index 000000000..4d8e28139
--- /dev/null
+++ b/pcr-testing/python-atpublic/PKGBUILD
@@ -0,0 +1,27 @@
+# Maintainer: bill-auger <bill-auger@programmer.net>
+# Maintainer (AUR): Simon Hanna <simon dot hanna AT serve-me DOT info>
+
+
+pkgname=('python-atpublic')
+pkgver=0.5
+pkgrel=1
+pkgdesc="python '@public' decorator for populating '__all__'"
+arch=(any)
+url=https://gitlab.com/warsaw/public
+license=('Apache')
+options=(!emptydirs)
+
+makedepends=('python-setuptools')
+
+_upstream_name='public'
+_release=${_upstream_name}-${pkgver}
+source=(https://gitlab.com/warsaw/${_upstream_name}/-/archive/${pkgver}/${_release}.tar.gz)
+sha256sums=('56b7878c84c90a6f95c24ddb5a71950a5f6024c4e4f143256bca8b57680bdc9b')
+
+
+package()
+{
+  cd "${srcdir}/${_release}"
+
+  python setup.py install --root="${pkgdir}/" --optimize=1
+}
diff --git a/pcr-testing/python-falcon/PKGBUILD b/pcr-testing/python-falcon/PKGBUILD
new file mode 100644
index 000000000..bbbfa54dc
--- /dev/null
+++ b/pcr-testing/python-falcon/PKGBUILD
@@ -0,0 +1,63 @@
+# Maintainer: bill-auger <bill-auger@programmer.net>
+# Maintainer (AUR): tocic <tocic at protonmail dot ch>
+# Contributor: Carl George < arch at cgtx dot us >
+
+
+#_check=1
+
+pkgname=('python-falcon' 'python2-falcon')
+pkgver=1.4.1
+pkgrel=1
+pkgdesc="An unladen web framework for building APIs and app backends."
+arch=('i686' 'x86_64')
+url=https://falconframework.org
+license=('Apache')
+
+makedepends=('cython' 'python-setuptools' 'cython2' 'python2-setuptools')
+[[ -v ${_run_check} ]] && checkdepends=('python-pytest>=3.0.1' 'python-jsonschema'
+                                        'python-msgpack' 'python-requests'
+                                        'python-six>=1.4.0' 'python-testtools' 'python-yaml'
+                                        'python2-pytest>=3.0.1' 'python2-jsonschema'
+                                        'python2-msgpack' 'python2-requests'
+                                        'python2-six>=1.4.0' 'python2-testtools' 'python2-yaml')
+
+_upstream_name='falcon'
+_release=${_upstream_name}-${pkgver}
+source=(https://files.pythonhosted.org/packages/source/${_upstream_name:0:1}/${_upstream_name}/${_release}.tar.gz)
+sha256sums=('3981f609c0358a9fcdb25b0e7fab3d9e23019356fb429c635ce4133135ae1bc4')
+
+
+build()
+{
+  cd "${srcdir}/${_release}"
+
+  python setup.py build
+  python2 setup.py build
+}
+
+check()
+{
+  cd "${srcdir}/${_release}"
+
+  if [[ -v _check ]] ; then pytest tests ; pytest2 tests ; fi ;
+}
+
+package_python-falcon()
+{
+  depends=('python-six>=1.4.0' 'python-mimeparse>=1.5.2')
+
+  cd "${srcdir}/${_release}"
+
+  python setup.py install --skip-build --root="${pkgdir}" --optimize=1
+}
+
+package_python2-falcon()
+{
+  depends=('python2-six>=1.4.0' 'python2-mimeparse>=1.5.2')
+
+  cd "${srcdir}/${_release}"
+
+  python2 setup.py install --skip-build --root="${pkgdir}" --optimize=1
+  mv "${pkgdir}/usr/bin/falcon-bench"        "${pkgdir}/usr/bin/falcon-bench-python2"
+  mv "${pkgdir}/usr/bin/falcon-print-routes" "${pkgdir}/usr/bin/falcon-print-routes-python2"
+}
diff --git a/pcr-testing/python-flufl-bounce/PKGBUILD b/pcr-testing/python-flufl-bounce/PKGBUILD
new file mode 100644
index 000000000..019cb991c
--- /dev/null
+++ b/pcr-testing/python-flufl-bounce/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: bill-auger <bill-auger@programmer.net>
+# Maintainer (AUR): Simon Hanna <simon dot hanna AT serve-me DOT info>
+
+
+pkgname=('python-flufl-bounce' 'python2-flufl-bounce')
+pkgver=2.3
+pkgrel=1
+pkgdesc="Email bounce detectors"
+arch=(any)
+url=https://launchpad.net/flufl.bounce
+license=('LGPL')
+options=(!emptydirs)
+
+makedepends=('python-setuptools' 'python2-setuptools')
+
+_upstream_name='flufl.bounce'
+_release=${_upstream_name}-${pkgver}
+source=(https://pypi.python.org/packages/source/${_upstream_name:0:1}/${_upstream_name}/${_release}.tar.gz)
+sha256sums=('6a2b7265af291eac41cb1022442ee65ff1c1f5af307bf8820a3f38cc86d29f99')
+
+
+package_python-flufl-bounce()
+{
+  depends=('python2')
+
+  cd "${srcdir}/${_release}"
+
+  python setup.py install --root="${pkgdir}/" --optimize=1
+}
+
+package_python2-flufl-bounce()
+{
+  depends=('python2')
+
+  cd "${srcdir}/${_release}"
+
+  python2 setup.py install --root="${pkgdir}/" --optimize=1
+}
diff --git a/pcr-testing/python-flufl-i18n/PKGBUILD b/pcr-testing/python-flufl-i18n/PKGBUILD
new file mode 100644
index 000000000..932c13cd6
--- /dev/null
+++ b/pcr-testing/python-flufl-i18n/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: bill-auger <bill-auger@programmer.net>
+# Maintainer (AUR): Simon Hanna <simon dot hanna AT serve-me DOT info>
+
+
+pkgname=('python-flufl-i18n' 'python2-flufl-i18n')
+pkgver=1.1.3
+pkgrel=1
+pkgdesc="A high level API for Python internationalization"
+arch=(any)
+url=https://launchpad.net/flufl.i18n
+license=('LGPL')
+options=(!emptydirs)
+
+makedepends=('python-setuptools' 'python2-setuptools')
+
+_upstream_name='flufl.i18n'
+_release=${_upstream_name}-${pkgver}
+source=(https://pypi.python.org/packages/source/${_upstream_name:0:1}/${_upstream_name}/${_release}.tar.gz)
+sha256sums=('bb743c1101936138edf6f6b0dd9f77f157ca6b5f38c608f440fd16b59c4c5130')
+
+
+package_python-flufl-i18n()
+{
+  depends=('python2')
+
+  cd "${srcdir}/${_release}"
+
+  python setup.py install --root="$pkgdir/" --optimize=1
+}
+
+package_python2-flufl-i18n()
+{
+  depends=('python2')
+
+  cd "${srcdir}/${_release}"
+
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+}
diff --git a/pcr-testing/python-flufl-lock/PKGBUILD b/pcr-testing/python-flufl-lock/PKGBUILD
new file mode 100644
index 000000000..789fe6b3b
--- /dev/null
+++ b/pcr-testing/python-flufl-lock/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: bill-auger <bill-auger@programmer.net>
+# Maintainer (AUR): Simon Hanna <simon dot hanna AT serve-me DOT info>
+
+
+pkgname=('python-flufl-lock' 'python2-flufl-lock')
+pkgver=2.4.1
+pkgrel=1
+pkgdesc="NFS-safe file locking with timeouts for POSIX systems"
+arch=(any)
+url=https://launchpad.net/flufl.lock
+license=('LGPL')
+options=(!emptydirs)
+
+makedepends=('python-setuptools' 'python2-setuptools')
+
+_upstream_name='flufl.lock'
+_release=${_upstream_name}-${pkgver}
+source=(https://pypi.python.org/packages/source/${_upstream_name:0:1}/${_upstream_name}/${_release}.tar.gz)
+sha256sums=('72639aca3ef0379aef125c7346b042691c3452152843f301801b3c2ddcac1032')
+
+
+package_python-flufl-lock()
+{
+  depends=('python')
+
+  cd "${srcdir}/${_release}"
+
+  python setup.py install --root="$pkgdir/" --optimize=1
+}
+
+package_python2-flufl-lock()
+{
+  depends=('python2')
+
+  cd "${srcdir}/${_release}"
+
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+}
diff --git a/pcr-testing/python-lazr-config/PKGBUILD b/pcr-testing/python-lazr-config/PKGBUILD
new file mode 100644
index 000000000..c312d5ec5
--- /dev/null
+++ b/pcr-testing/python-lazr-config/PKGBUILD
@@ -0,0 +1,40 @@
+# Maintainer: bill-auger <bill-auger@programmer.net>
+# Maintainer (AUR): Simon Hanna <simon dot hanna AT serve-me DOT info>
+
+
+pkgname=('python-lazr-config' 'python2-lazr-config')
+pkgver=2.1
+pkgrel=1
+pkgdesc="Is typically used to manage process configuration"
+arch=(any)
+url=https://launchpad.net/lazr.config
+license=('LGPL')
+options=(!emptydirs)
+
+makedepends=('python-setuptools' 'python2-setuptools')
+
+_upstream_name='lazr.config'
+_release=${_upstream_name}-${pkgver}
+source=(https://pypi.python.org/packages/source/${_upstream_name:0:1}/${_upstream_name}/${_release}.tar.gz)
+sha256sums=('5f380f5defd1f2e0db7483f5b55072e458dcba1d38ea8b2c7867de8127970689')
+
+
+package_python-lazr-config()
+{
+  depends=('python' 'python-lazr-delegates' 'python-nose' 'python-setuptools'
+           'python-zope-interface')
+
+  cd "${srcdir}/${_release}"
+
+  python setup.py install --root="$pkgdir/" --optimize=1
+}
+
+package_python2-lazr-config()
+{
+  depends=('python2' 'python2-lazr-delegates' 'python2-nose' 'python2-setuptools'
+           'python2-zope-interface')
+
+  cd "${srcdir}/${_release}"
+
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+}
diff --git a/pcr-testing/python-lazr-delegates/PKGBUILD b/pcr-testing/python-lazr-delegates/PKGBUILD
new file mode 100644
index 000000000..73f68d29a
--- /dev/null
+++ b/pcr-testing/python-lazr-delegates/PKGBUILD
@@ -0,0 +1,37 @@
+# Maintainer: bill-auger <bill-auger@programmer.net>
+# Maintainer (AUR): Simon Hanna <simon dot hanna AT serve-me DOT info>
+
+
+pkgname=('python-lazr-delegates' 'python2-lazr-delegates')
+pkgver=2.0.3
+pkgrel=1
+pkgdesc="Easily write objects that delegate behavior"
+arch=(any)
+url=https://launchpad.net/lazr.delegates
+license=('LGPL')
+options=(!emptydirs)
+
+makedepends=('python-setuptools' 'python2-setuptools')
+
+_upstream_name='lazr.delegates'
+_release=${_upstream_name}-${pkgver}
+source=(https://pypi.python.org/packages/source/${_upstream_name:0:1}/${_upstream_name}/${_release}.tar.gz)
+sha256sums=('51c80d5ac2c1f8f4a8c75fa271646529c8a6393a0b088dab50fb62138d092ee9')
+
+
+package_python-lazr-delegates()
+{
+  depends=('python' 'python-setuptools' 'python-zope-interface' 'python-nose')
+
+  cd "${srcdir}/${_release}"
+
+  python setup.py install --root="$pkgdir/" --optimize=1
+}
+
+package_python2-lazr-delegates() {
+  depends=('python2' 'python2-setuptools' 'python2-zope-interface' 'python2-nose')
+
+  cd "${srcdir}/${_release}"
+
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+}
diff --git a/pcr-testing/python-lazr-smtptest/PKGBUILD b/pcr-testing/python-lazr-smtptest/PKGBUILD
new file mode 100644
index 000000000..b818d4ceb
--- /dev/null
+++ b/pcr-testing/python-lazr-smtptest/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: bill-auger <bill-auger@programmer.net>
+# Maintainer (AUR): Simon Hanna <simon dot hanna AT serve-me DOT info>
+
+
+pkgname=('python-lazr-smtptest' 'python2-lazr-smtptest')
+pkgver=2.0.3
+pkgrel=1
+pkgdesc="A framework for testing SMTP-based applications and libraries"
+arch=(any)
+url=https://launchpad.net/lazr.smtptest
+license=('LGPL')
+options=(!emptydirs)
+
+makedepends=('python-setuptools' 'python2-setuptools')
+
+_upstream_name='lazr.smtptest'
+_release=${_upstream_name}-${pkgver}
+source=(https://pypi.python.org/packages/source/${_upstream_name:0:1}/${_upstream_name}/${_release}.tar.gz)
+sha256sums=('9dca1890677a7fd022b1e36ea52dd22cea8bd3a3f2decb5b9625207b8ebf6e15')
+
+
+package_python-lazr-smtptest()
+{
+  depends=('python2')
+
+  cd "${srcdir}/${_release}"
+
+  python setup.py install --root="$pkgdir/" --optimize=1
+}
+
+package_python2-lazr-smtptest()
+{
+  depends=('python2')
+
+  cd "${srcdir}/${_release}"
+
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+}
diff --git a/pcr-testing/python-mailman-client/PKGBUILD b/pcr-testing/python-mailman-client/PKGBUILD
new file mode 100644
index 000000000..29d4b87ad
--- /dev/null
+++ b/pcr-testing/python-mailman-client/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: bill-auger <bill-auger@programmer.net>
+# Maintainer (AUR): Simon Hanna <simon dot hanna AT serve-me DOT info>
+
+
+pkgname=('python-mailman-client' 'python2-mailman-client')
+pkgver=3.2.0
+pkgrel=1
+pkgdesc="Library that provides official Python bindings for the GNU Mailman 3 REST API"
+arch=(any)
+url=https://gitlab.com/mailman/mailmanclient
+license=('LGPL')
+options=(!emptydirs)
+
+makedepends=('python-setuptools' 'python2-setuptools')
+
+_upstream_name='mailmanclient'
+_release="${_upstream_name}-${pkgver}"
+source=(https://gitlab.com/mailman/${_upstream_name}/-/archive/${pkgver}/${_release}.tar.gz)
+sha256sums=('12fdfd96ec46a3c38bf1227787f97d9547dec3d8501a26177c98b1a67a5e9999')
+
+
+package_python-mailmanclient()
+{
+  depends=('python' 'python-six' 'python-httplib2')
+
+  cd "$srcdir/${_release}"
+
+  python setup.py install --root="$pkgdir/" --optimize=1
+}
+
+package_python2-mailmanclient()
+{
+  depends=('python2' 'python2-six' 'python2-httplib2')
+
+  cd "$srcdir/${_release}"
+
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+}
diff --git a/pcr-testing/python-mailman-hyperkitty-plugin/PKGBUILD b/pcr-testing/python-mailman-hyperkitty-plugin/PKGBUILD
new file mode 100644
index 000000000..24fb78252
--- /dev/null
+++ b/pcr-testing/python-mailman-hyperkitty-plugin/PKGBUILD
@@ -0,0 +1,27 @@
+# Maintainer: bill-auger <bill-auger@programmer.net>
+# Maintainer (AUR): Simon Hanna <simon dot hanna AT serve-me DOT info>
+
+pkgname=('python-mailman-hyperkitty-plugin')
+pkgver=1.1.0
+pkgrel=1
+pkgdesc="Hyperkitty archive plugin for mailman"
+arch=(any)
+url=https://gitlab.com/mailman/mailman-hyperkitty
+license=('GPL')
+options=(!emptydirs)
+
+makedepends=('python-setuptools')
+depends=('mailman-core' 'python-setuptools' 'python-requests')
+
+_upstream_name='mailman-hyperkitty'
+_release="${_upstream_name}-v${pkgver}"
+source=(https://gitlab.com/mailman/${_upstream_name}/-/archive/v${pkgver}/${_release}.tar.gz)
+sha256sums=('b3a32e66961571c3b68f536cf50dbd186620577dd16024e67d299a0857e1d40d')
+
+
+package()
+{
+  cd "$srcdir/${_release}"
+
+  python setup.py install --root="${pkgdir}/" --optimize=1
+}
diff --git a/pcr-testing/python2-django-hyperkitty/PKGBUILD b/pcr-testing/python2-django-hyperkitty/PKGBUILD
new file mode 100644
index 000000000..522eb88d9
--- /dev/null
+++ b/pcr-testing/python2-django-hyperkitty/PKGBUILD
@@ -0,0 +1,31 @@
+# Maintainer: bill-auger <bill-auger@programmer.net>
+# Maintainer (AUR): Simon Hanna <simon dot hanna AT serve-me DOT info>
+
+pkgname=('python2-django-hyperkitty')
+pkgver=1.2.1
+pkgrel=1
+pkgdesc="A Django app that provides a web user interface to access GNU Mailman archives"
+arch=(any)
+url=https://gitlab.com/mailman/hyperkitty
+license=('GPL')
+options=(!emptydirs)
+
+makedepends=('python2-setuptools')
+depends=('python2-mailmanclient' 'python2-django-crispy-forms' 'python2-django-rest-framework'
+         'python2-social-auth' 'python2-django-gravatar' 'python2-django-paintstore'
+         'python2-django-compressor' 'python2-django-browserid' 'python2-django-haystack'
+         'python2-pytz' 'python2-dateutil' 'python2-enum34' 'python2-networkx'
+         'python2-robot-detection' 'python2-django-extensions' 'sassc')
+
+_upstream_name='hyperkitty'
+_release="${_upstream_name}-v${pkgver}"
+source=(https://gitlab.com/mailman/${_upstream_name}/-/archive/v${pkgver}/${_release}.tar.gz)
+sha256sums=('b5d0064a2af3f36b055f7aa07f6f0828776d3437357ecb2e9b7d5d4e5bbceaf9')
+
+
+package()
+{
+  cd "$srcdir/${_release}"
+
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+}
diff --git a/pcr-testing/python2-django-mailman3/PKGBUILD b/pcr-testing/python2-django-mailman3/PKGBUILD
new file mode 100644
index 000000000..e4a6896b8
--- /dev/null
+++ b/pcr-testing/python2-django-mailman3/PKGBUILD
@@ -0,0 +1,27 @@
+# Maintainer: bill-auger <bill-auger@programmer.net>
+# Maintainer (AUR): Simon Hanna <simon dot hanna AT serve-me DOT info>
+
+pkgname=('python2-django-mailman3')
+pkgver=1.2.0
+pkgrel=1
+pkgdesc="Django library to help interaction with Mailman"
+arch=(any)
+url=https://gitlab.com/mailman/django-mailman3
+license=('GPL3')
+options=(!emptydirs)
+
+depends=('python2' 'python2-django' 'python2-django-allauth' 'python2-future'
+         'python2-mailmanclient' 'python2-pytz' 'python2-django-gravatar')
+
+_upstream_name='django-mailman3'
+_release="${_upstream_name}-${pkgver}"
+source=(https://gitlab.com/mailman/${_upstream_name}/-/archive/${pkgver}/${_release}.tar.gz)
+sha256sums=('fee336f22cef644cb9e1d9d1081ca58f96f6c9334d33df9b4df7e68d04754536')
+
+
+package()
+{
+  cd "$srcdir/${_release}"
+
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+}
diff --git a/pcr-testing/python2-django-postorius/PKGBUILD b/pcr-testing/python2-django-postorius/PKGBUILD
new file mode 100644
index 000000000..35c01a07b
--- /dev/null
+++ b/pcr-testing/python2-django-postorius/PKGBUILD
@@ -0,0 +1,27 @@
+# Maintainer: bill-auger <bill-auger@programmer.net>
+# Maintainer (AUR): Simon Hanna <simon dot hanna AT serve-me DOT info>
+
+pkgname=('python2-django-postorius')
+pkgver=1.2.2
+pkgrel=1
+pkgdesc="A Django app that provides a web user interface to access GNU Mailman"
+arch=(any)
+url=https://gitlab.com/mailman/postorius
+license=('LGPL')
+options=(!emptydirs)
+
+makedepends=('python2-setuptools')
+depends=('python2' 'python2-django-mailman3')
+
+_upstream_name='postorius'
+_release="${_upstream_name}-${pkgver}"
+source=(https://gitlab.com/mailman/${_upstream_name}/-/archive/${pkgver}/${_release}.tar.gz)
+sha256sums=('4299c883a7e1a5044436a3c57a19bf337bd95b4e1b89fe6c66982843622d464e')
+
+
+package()
+{
+  cd "$srcdir/${_release}"
+
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+}