blob: c377b6e63dd92bf523eb1f37a9b78b7ac6b486e5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Maintainer (Arch): Sonny Piers <sonny.piers@gmail.com>
# Contributor (Arch): Tim Besard <tim.besard@gmail.com>
pkgname=spectrum
pkgver=1.4.8
pkgrel=1
pkgdesc="XMPP libpurple transport/gateway."
arch=('i686' 'x86_64' 'mips64el')
url="http://spectrum.im"
license=('GPL')
depends=('gloox' 'libpurple-minimal' 'poco' 'python2' 'libev')
makedepends=('cmake' 'gettext' 'pkg-config')
optdepends=('mysql: MySQL database backend support'
'postgresql-libs: PostgreSQL database backend support'
'sqlite3: SQLite database backend support'
'libevent: support for libevent'
'imagemagick: support for avatars synchronization with legacy networks'
# Protocols plugins
'mbpurple-svn: microblogging services support (like Twitter or identi.ca/StatusNet)'
'msn-pecan: a different implementation of the MSN protocol for libpurple'
'pidgin-facebookchat: Facebook support, with more features than Facebook XMPP server'
'pidgin-sipe: SIPE protocol support'
)
backup=('etc/conf.d/spectrum')
source=('http://spectrum.im/attachments/download/43/spectrum-1.4.8.tar.gz'
'logrotate.spectrum')
md5sums=('edd88e1e70f86fe9aa4b43d787529a47'
'4f9cbfe3878fe5f4137d1bb5acc9e850')
install='spectrum.install'
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
msg "Starting make..."
cmake -DCMAKE_INSTALL_PREFIX:PATH=/usr .
make
cd spectrumctl
python2 setup.py build
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
# Various needed folders -- correct permissions are set in spectrum.install
install -d "${pkgdir}/etc/spectrum"
install -d "${pkgdir}/var/log/spectrum"
install -d "${pkgdir}/var/run/spectrum"
install -d "${pkgdir}/var/lib/spectrum"
# Install binaries and Python control script
make DESTDIR="${pkgdir}" install
cd spectrumctl
python2 setup.py install --root="${pkgdir}"
# Install initscript and logrotate config
install -Dm755 "${srcdir}/${pkgname}-${pkgver}/initscripts/archlinux/spectrum-rc.d" "${pkgdir}/etc/rc.d/spectrum"
install -Dm644 "${srcdir}/${pkgname}-${pkgver}/initscripts/archlinux/spectrum-conf.d" "${pkgdir}/etc/conf.d/spectrum"
install -Dm644 "${srcdir}/logrotate.spectrum" "${pkgdir}/etc/logrotate.d/spectrum"
# Patch to use python2
sed -i -e "s|#!/usr/bin/env python|#!/usr/bin/env python2|" "${pkgdir}/usr/bin/spectrumctl"
}
|
