blob: 8fdf374c5fd8aa2819ba42d48e48e4676e8ba52d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
|
# $Id$
# Maintainer (Arch): Tom Gundersen <teg@jklm.no>
# Maintainer (Arch): Dave Reisner <dreisner@archlinux.org>
# Contributor (Arch): judd <jvinet@zeroflux.org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
pkgbase=util-linux-nosystemd
pkgname=(util-linux-nosystemd libutil-linux-nosystemd)
_pkgmajor=2.30
pkgver=${_pkgmajor}.1
pkgrel=2
pkgdesc="Miscellaneous system utilities for Linux"
url="https://www.kernel.org/pub/linux/utils/util-linux/"
arch=('i686' 'x86_64' 'armv7h')
makedepends=('eudev' 'python' 'libcap-ng')
license=('GPL2')
options=('strip' 'debug')
validpgpkeys=('B0C64D14301CC6EFAEDF60E4E4B71D5EEC39C284') # Karel Zak
source=("https://www.kernel.org/pub/linux/utils/util-linux/v$_pkgmajor/${pkgbase%-nosystemd}-$pkgver.tar."{xz,sign}
pam-{login,common,su}
'util-linux.sysusers')
md5sums=('5e5ec141e775efe36f640e62f3f8cd0d'
'SKIP'
'4368b3f98abd8a32662e094c54e7f9b1'
'a31374fef2cba0ca34dfc7078e2969e4'
'fa85e5cce5d723275b14365ba71a8aad'
'dfc9904f67ebc54bb347ca3cc430ef2b')
build() {
cd "${pkgbase%-nosystemd}-$pkgver"
./configure --prefix=/usr \
--libdir=/usr/lib \
--bindir=/usr/bin \
--localstatedir=/run \
--enable-fs-paths-extra=/usr/bin \
--enable-raw \
--enable-vipw \
--enable-newgrp \
--enable-chfn-chsh \
--enable-write \
--enable-mesg \
--with-python=3
make
}
package_util-linux-nosystemd() {
conflicts=('util-linux' 'eject' 'zramctl')
provides=("util-linux=$pkgver" 'eject' 'zramctl')
replaces=('zramctl')
depends=('pam' 'shadow' 'coreutils' 'libeudev' 'libcap-ng' 'libutil-linux')
optdepends=('python: python bindings to libmount')
#groups=('base' 'base-devel')
backup=(etc/pam.d/chfn
etc/pam.d/chsh
etc/pam.d/login
etc/pam.d/su
etc/pam.d/su-l)
cd "${pkgbase%-nosystemd}-$pkgver"
make DESTDIR="$pkgdir" install
# setuid chfn and chsh
chmod 4755 "$pkgdir"/usr/bin/{newgrp,ch{sh,fn}}
# install PAM files for login-utils
install -Dm644 "$srcdir/pam-common" "$pkgdir/etc/pam.d/chfn"
install -m644 "$srcdir/pam-common" "$pkgdir/etc/pam.d/chsh"
install -m644 "$srcdir/pam-login" "$pkgdir/etc/pam.d/login"
install -m644 "$srcdir/pam-su" "$pkgdir/etc/pam.d/su"
install -m644 "$srcdir/pam-su" "$pkgdir/etc/pam.d/su-l"
# adjust for usrmove
# TODO(dreisner): fix configure.ac upstream so that this isn't needed
cd "$pkgdir"
mv {,usr/}sbin/* usr/bin
rmdir sbin usr/sbin
### runtime libs are shipped as part of libutil-linux
rm "$pkgdir"/usr/lib/lib*.{a,so}*
### install sysusers
install -Dm644 "$srcdir/util-linux.sysusers" \
"$pkgdir/usr/lib/sysusers.d/util-linux.conf"
}
package_libutil-linux-nosystemd() {
pkgdesc="util-linux runtime libraries"
provides=("libutil-linux=$pkgver" 'libblkid.so' 'libfdisk.so' 'libmount.so' 'libsmartcols.so' 'libuuid.so')
conflicts=('libutil-linux')
make -C "${pkgbase%-nosystemd}-$pkgver" DESTDIR="$pkgdir" install-usrlib_execLTLIBRARIES
}
|
