blob: ed88ed36bdc156386839e51464e8cb2a8f97294c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
|
# Maintainer (Arch): Anatol Pomozov <anatol.pomozov@gmail.com>
# Contributor: Andreas Grapentin <andreas@grapentin.org>
# parabola changes and rationale:
# - adapted from aarch64-linux-gnu-gcc
# - this is only used to bootstrap the toolchain, since you need gcc to compile
# glibc, and glibc to compile gcc, we have this package as a 'stage1' gcc build
# to create the initial glibc and the 'real' gcc
_target=riscv64-linux-gnu
pkgname=$_target-gcc-bootstrap
pkgver=7.3.1
_islver=0.18
pkgrel=2
_snapshot=7-20180215
pkgdesc='The GNU Compiler Collection - cross compiler for riscv64 target - bootstrap version. only used to build initial glibc and compiler'
arch=(x86_64)
url='http://gcc.gnu.org/'
license=(GPL LGPL FDL)
depends=($_target-binutils libmpc zlib)
makedepends=(gmp mpfr)
options=(!emptydirs !strip)
provides=(${pkgname%-bootstrap})
conflicts=(${pkgname%-bootstrap})
source=(#ftp://gcc.gnu.org/pub/gcc/releases/gcc-$pkgver/gcc-$pkgver.tar.bz2
ftp://gcc.gnu.org/pub/gcc/snapshots/$_snapshot/gcc-$_snapshot.tar.xz
http://isl.gforge.inria.fr/isl-$_islver.tar.bz2)
sha256sums=('bb276f6fce4822fc0806d1e87d21245854d1e41f2a7027c7288375084176c679'
'6b8b0fd7f81d0a957beb3679c81bbb34ccc7568d5682844d8924424a0dadcb1b')
if [ -n "$_snapshot" ]; then
_basedir=gcc-$_snapshot
else
_basedir=gcc-$pkgver
fi
prepare() {
cd $_basedir
# link isl for in-tree builds
ln -sf ../isl-$_islver isl
echo $pkgver > gcc/BASE-VER
# Do not run fixincludes
sed -i 's@\./fixinc\.sh@-c true@' gcc/Makefile.in
# hack! - some configure tests for header files using "$CPP $CPPFLAGS"
sed -i "/ac_cpp=/s/\$CPPFLAGS/\$CPPFLAGS -O2/" "$srcdir"/$_basedir/{libiberty,gcc}/configure
rm -rf $srcdir/gcc-build
mkdir $srcdir/gcc-build
}
build() {
cd gcc-build
# using -pipe causes spurious test-suite failures
# http://gcc.gnu.org/bugzilla/show_bug.cgi?id=48565
CFLAGS=${CFLAGS/-pipe/}
CXXFLAGS=${CXXFLAGS/-pipe/}
$srcdir/$_basedir/configure \
--prefix=/usr \
--program-prefix=$_target- \
--with-local-prefix=/usr/$_target \
--with-sysroot=/usr/$_target \
--with-build-sysroot=/usr/$_target \
--libdir=/usr/lib --libexecdir=/usr/lib \
--target=$_target --host=$CHOST --build=$CHOST \
--with-newlib \
--without-headers \
--disable-shared \
--disable-threads \
--with-system-zlib \
--enable-tls \
--enable-languages=c \
--disable-libatomic \
--disable-libmudflap \
--disable-libssp \
--disable-libquadmath \
--disable-libgomp \
--disable-nls \
--disable-bootstrap \
--enable-checking=release \
--disable-multilib
make inhibit-libc=true all-gcc
make inhibit-libc=true all-target-libgcc
}
package() {
cd gcc-build
make DESTDIR="$pkgdir" inhibit-libc=true install-gcc
make DESTDIR="$pkgdir" inhibit-libc=true install-target-libgcc
# strip target binaries
find "$pkgdir"/usr/lib/gcc/$_target/ -type f -and \( -name \*.a -or -name \*.o \) -exec $_target-objcopy -R .comment -R .note -R .debug_info -R .debug_aranges -R .debug_pubnames -R .debug_pubtypes -R .debug_abbrev -R .debug_line -R .debug_str -R .debug_ranges -R .debug_loc '{}' \;
# strip host binaries
find "$pkgdir"/usr/bin/ "$pkgdir"/usr/lib/gcc/$_target/ -type f -and \( -executable \) -exec strip '{}' \;
# Remove files that conflict with host gcc package
rm -r "$pkgdir"/usr/share/man/man7
rm -r "$pkgdir"/usr/share/info
}
|
