blob: e10d00c34309a939eed8e6142f9aeeb0cd0c1402 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer (Arch): carstene1ns <arch carsten-teibes de> - http://git.io/ctPKG
# Maintainer: André Silva <emulatorman@parabola.nu>
# Maintainer: Márcio Silva <coadde@parabola.nu>
pkgname=reicast-git
pkgver=r1322.4b94e2f
pkgrel=1
pkgdesc="A multiplatform Sega Dreamcast emulator"
arch=('i686' 'x86_64')
url="http://reicast.com/"
license=('GPL2')
conflicts=('reicast')
provides=('reicast')
makedepends=('git')
depends=('libgl' 'alsa-plugins')
optdepends=('xboxdrv: Userspace gamepad driver for Xbox and Xbox360 gamepads'
'antimicro: Graphical program used to map keyboard keys and mouse controls to gamepad buttons')
source=(reicast::"git+https://github.com/reicast/reicast-emulator.git"
'enable_joystick_support.patch'
'wait_if_two_frames_already_in_flight.patch')
sha256sums=('SKIP'
'464946512ca4cffac104128a85dd174520caeaa0325afbf281b6cfdbc0120fc6'
'f4d3b4ad7703da09dc59cae839ca225e1a21b89d905ede3519bf3174b40903da')
pkgver() {
cd reicast
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare () {
cd reicast
patch -Np1 -i "$srcdir"/enable_joystick_support.patch
patch -Np1 -i "$srcdir"/wait_if_two_frames_already_in_flight.patch
# Fix pointer size on 64 bit arch: http://github.com/reicast-emulator/pull/768
sed -i 's|verify((int)rbi);|verify((size_t)rbi);|' core/hw/sh4/dyna/driver.cpp
# Add experimental shadow support: http://github.com/reicast-emulator/issues/94
sed -i 's|//DrawModVols|DrawModVols|' core/rend/gles/gldraw.cpp
}
build () {
make -C reicast/shell/linux
if [[ $CARCH == x86_64 ]]; then
make -C reicast/shell/linCPP
fi
}
package () {
cd reicast
install -Dm755 shell/linux/reicast.elf "$pkgdir"/usr/bin/reicast
install -Dm755 shell/linux/nosym-reicast.elf "$pkgdir"/usr/bin/reicast-nosym
if [[ $CARCH == x86_64 ]]; then
install -Dm755 shell/linCPP/reicast.elf "$pkgdir"/usr/bin/reicast-cpp
install -Dm755 shell/linCPP/nosym-reicast.elf "$pkgdir"/usr/bin/reicast-nosym-cpp
fi
install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
|
