blob: cf93077d33e83d996bbfbf485c89d8da1d4214a9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# $Id$
# Maintainer (AUR): Felix Yan <felixonmars@archlinux.org>
# Contributor (AUR): grimsock <lord.grimsock at gmail dot com>
# Contributor (AUR): Dieter Plaetinck <dieter@plaetinck.be>
# Contributor (AUR): Vladimir Chizhov <jagoterr@gmail.com>
# Contributor (AUR): Henry Tang <henryykt@gmail.com>
pkgname=phantomjs
pkgver=2.1.1
pkgrel=11
pkgdesc="Headless WebKit with JavaScript API"
url="http://www.phantomjs.org/"
license=('BSD' 'LGPL' 'MIT')
arch=('x86_64' 'i686')
depends=('icu>=61' 'icu<62' 'libjpeg-turbo' 'libpng' 'fontconfig' 'gperf' 'ruby' 'python2' 'openssl-1.0')
makedepends=('git')
source=("git+https://github.com/ariya/${pkgname}.git#tag=$pkgver"
icu59.patch)
sha512sums=('SKIP'
'e349a14c5d32e5627f28be6ebd20104370ec6b7f086f670e7f19b484b38839220cfeb49178765f38d918d05fb889bbc990f8a3809db6d9e1cbde0af5b9dd923b')
prepare() {
cd $pkgname
git submodule update --init
patch -Np1 -d src/qt/qtwebkit <../icu59.patch
mkdir "$srcdir/python2-path"
ln -s /usr/bin/python2 "$srcdir/python2-path/python"
}
build() {
cd $pkgname
export PATH="$srcdir/python2-path:$PATH" PYTHON=/usr/bin/python2
export CXXFLAGS+=" -I/usr/include/openssl-1.0"
export OPENSSL_LIBS='-L/usr/lib/openssl-1.0 -lssl -lcrypto'
CFLAGS+=" -Wno-expansion-to-defined"
CXXFLAGS+=" -Wno-expansion-to-defined"
python2 build.py --confirm --release --qt-config='-no-rpath'
}
package() {
install -Dm755 "$srcdir/$pkgname/bin/phantomjs" "$pkgdir/usr/bin/phantomjs"
mkdir -p "$pkgdir/usr/share/$pkgname"
cp -r "$srcdir/$pkgname/examples" "$pkgdir/usr/share/$pkgname"/
install -Dm644 "$srcdir/$pkgname/LICENSE.BSD" "$pkgdir/usr/share/licenses/$pkgname/LICENSE.BSD"
install -Dm644 "$srcdir/$pkgname/third-party.txt" "$pkgdir/usr/share/licenses/$pkgname/third-party.txt"
}
|
