blob: aaff37af76e60a3008f225bbbf8d3c9c7b34144b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
_pkgname=osgi.compendium
pkgname=osgi-compendium
pkgver=5.0.0
pkgrel=1
pkgdesc="Java OSGi API - Compendium module"
arch=('any')
url='https://www.osgi.org/developer/specifications/'
license=('APACHE')
depends=('java-runtime')
makedepends=('java-geronimo-jpa' 'java-environment' 'jh' 'osgi-core' 'osgi-foundation-ee' 'tomcat8')
source=("https://repo1.maven.org/maven2/org/osgi/org.${_pkgname}/${pkgver}/org.${_pkgname}-${pkgver}-sources.jar"
"https://repo1.maven.org/maven2/org/osgi/org.${_pkgname}/${pkgver}/org.${_pkgname}-${pkgver}.pom"
'LICENSE.txt')
sha1sums=('3f5760f4c64374f86e4071adae75e0db055eec84'
'8d87c0739cfd003228420f1ab5300bd07bb26f0f'
'5a7d7df655ba40478fae80a6abafc6afc36f9b6a')
prepare() {
cd ${srcdir}
mkdir -p build/classes
}
build() {
cd ${srcdir}
CLASSPATH="/usr/share/java/ee.foundation.jar:/usr/share/java/geronimo-jpa_2.0_spec.jar"
CLASSPATH="$CLASSPATH:/usr/share/java/osgi.core.jar:/usr/share/java/tomcat8/servlet-api.jar"
javac -cp $CLASSPATH -d build/classes -encoding UTF-8 \
$(find . -name \*.java)
javadoc -classpath $CLASSPATH -d "build/javadoc" -encoding UTF-8 \
-sourcepath . -subpackages org
jar -cvf "${_pkgname}.jar" -C build/classes .
}
package() {
cd ${srcdir}
# Install license file
install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
# Install documentation
install -d "${pkgdir}/usr/share/doc/${pkgname}"
cp -r build/javadoc "${pkgdir}/usr/share/doc/${pkgname}"
# Install Maven artifacts
export DESTDIR=${pkgdir}
jh mvn-install org.osgi "org.${_pkgname}" ${pkgver} \
"org.${_pkgname}-${pkgver}.pom" \
"${_pkgname}.jar" \
"${_pkgname}-${pkgver}.jar"
ln -s "/usr/share/java/${_pkgname}-${pkgver}.jar" \
"${pkgdir}/usr/share/java/${_pkgname}.jar"
}
|
