blob: c679fb520556bc83e72f3d588ceb17774bdd3671 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Copyright (C) 2020 Denis 'GNUtoo' Carikli <GNUtoo@cyberdimension.org>
# This program is free software: you can redistribute it and/or modify
# it under the terms of the CC0 1.0 License.
# Maintainers: Parabola hackers <dev@lists.parabola.nu>
pkgname=nvramtool
# The Coreboot source code contains nonfree software: when running
# './download coreboot default' in the libreboot build system (lbmk),
# it removes some files with nonfree code inside like AMD microcode
# updates for instance. So to not redistribute nonfree code (in the
# package source), we use Libreboot source code.
#
# TODO: Either deblob coreboot sources ourselves with the Libreboot
# scripts or add support for releasing nvramtool source tarballs
# corresponding to specific Coreboot releases in Libreboot.
_libreboot_pkgver=20211122
pkgver=4.15+${_libreboot_pkgver}
pkgrel=1
pkgdesc="Reads and writes coreboot parameters and displaying information from the coreboot table in CMOS/NVRAM."
arch=('armv7h' 'i686' 'x86_64')
url="https://www.coreboot.org/Nvramtool"
license=('GPL2') # GPLv2-only according to the Coreboot README
# According to the Libreboot maintainer, we are supposed to use
# any of the mirrors in https://libreboot.org/download.html#https
# and not use the rsync server. The rsync server is only supposed
# to be used by mirrors as it has limited bandwith.
_mirror="https://mirrors.mit.edu/libreboot/"
source=("${_mirror}/testing/${_libreboot_pkgver}/libreboot-${_libreboot_pkgver}_src.tar.xz"
"${_mirror}/testing/${_libreboot_pkgver}/libreboot-${_libreboot_pkgver}_src.tar.xz.sig")
sha256sums=('e8a610e51e668c34627a6d9c048c554592fd2c2ab4dbcad83c85c06d132e5ad1'
'4442fc225383e1edf8f45e1aecba81868ae43db19978f15c17828389364c0434')
sha512sums=('3eac75b33bc6d2874c3ca1ad2392db7287992cf91d37879bb3244dbd6716bc7ffa3f8d31e15d821899e91a55b6fe665d918bea4e9da92e5e98345e9bcbe1bb95'
'3a532ecef550ef27b723845544e91ff6b13ed6f2f1188d40fdeb7b3c416be619ff58103c3b01cd52ff88c28df6d419d2113b92d0b8ba36d1a74cfc16f70e0e63')
validpgpkeys=('98CCDDF8E56047F475C044BDD0C62464FA8B4856') # Leah Rowe <info@minifree.org>
prepare() {
cd "$srcdir/libreboot-${_libreboot_pkgver}_src/coreboot/default/util/${pkgname}/"
sed 's#/sbin#/bin#' -i Makefile
}
build() {
cd "$srcdir/libreboot-${_libreboot_pkgver}_src/coreboot/default/util/${pkgname}/"
make
}
package() {
cd "$srcdir/libreboot-${_libreboot_pkgver}_src/coreboot/default/util/${pkgname}/"
make DESTDIR=$pkgdir PREFIX=/usr install
}
|
