blob: f2dd4563c3ab57b34c84d75686f0e3d8e019b629 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer(AUR): Graham Edgecombe <gpe@grahamedgecombe.com>
# Maintainer: Denis 'GNUtoo' Carikli <GNUtoo@cyberdimension.org>
# parabola changes and rationale:
# - Fixed "error while loading shared libraries: libboost_python37.so.1.69.0"
# by switching from boost-libs to boost1.69-libs
# TODO: see if this needs to be sent to the nextpnr-git AUR maintainer
pkgname=nextpnr-git
pkgver=r2284.08cf545
pkgrel=1
pkgdesc='Portable FPGA place and route tool'
arch=('i686' 'x86_64')
url='https://github.com/YosysHQ/nextpnr'
license=('custom:ISC')
depends=('boost1.69-libs' 'python' 'qt5-base')
makedepends=('boost' 'cmake' 'eigen' 'git' 'icestorm' 'trellis')
provides=('nextpnr')
conflicts=('nextpnr')
source=('nextpnr::git+https://github.com/YosysHQ/nextpnr.git')
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/nextpnr"
printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd "$srcdir/nextpnr"
mkdir -p build
cd build
cmake \
-DARCH=generic\;ice40\;ecp5 \
-DICEBOX_ROOT=/usr/share/icebox \
-DTRELLIS_ROOT=/usr/share/trellis \
-DBUILD_TESTS=ON \
-DCMAKE_BUILD_TYPE=RelWithDebInfo \
-DCMAKE_INSTALL_PREFIX=/usr \
-DUSE_OPENMP=ON \
..
make
}
check() {
cd "$srcdir/nextpnr/build"
make test
}
package() {
cd "$srcdir/nextpnr/build"
make DESTDIR="$pkgdir" install
install -Dm644 ../COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}
|
