blob: 962f30ae8ce12cc50056f235450338543b5ba9e4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: David P. <megver83@parabola.nu>
pkgname=liblinphone
pkgver=4.4.0
pkgrel=1
pkgdesc='A high-level SIP library'
arch=(x86_64 i686)
url='http://www.linphone.org'
license=('GPL')
depends=(belcard belle-sip mediastreamer xerces-c lime)
makedepends=(cmake doxygen graphviz python-pystache python-sphinx xsd)
source=("https://gitlab.linphone.org/BC/public/$pkgname/-/archive/$pkgver/$pkgname-$pkgver.tar.gz")
sha256sums=('a9a468e7e15ad59062d6460b7d2f6b1f1cd74c15d54a7b5dae6bad28a489cf40')
build() {
cd "$pkgname-$pkgver"
CXXFLAGS+=" -Wno-deprecated -Wimplicit-fallthrough=0 -Wno-unused-function"
cmake -DCMAKE_INSTALL_PREFIX=/usr \
-DENABLE_STATIC=NO \
-DENABLE_CXX_WRAPPER=YES \
-DENABLE_DOC=NO \
-DENABLE_LIME=YES \
-DENABLE_UNIT_TESTS=NO \
-DENABLE_STRICT=NO \
-DCMAKE_INSTALL_RPATH=NO .
make
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
sed -i "${srcdir//\//\\/}\/$pkgname-$pkgver\/wrappers\/cpp\/include/d" \
"$pkgdir/usr/share/LinphoneCxx/cmake/LinphoneCxxConfig.cmake"
}
|
