blob: 93265ce219aa1fb1ca9ac91caf6ed2d5fd320ba5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# $Id: PKGBUILD 107172 2014-03-14 00:14:28Z heftig $
# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
pkgname=gnash
pkgdesc="A GNU Flash movie player"
pkgver=0.8.11dev
pkgrel=2
arch=(i686 x86_64)
url="http://www.gnu.org/software/gnash/"
license=(GPL3)
depends=(curl giflib sdl agg libjpeg libpng libltdl libgl glu speex fontconfig cairo ffmpeg jemalloc boost-libs gtk2 libldap hicolor-icon-theme desktop-file-utils gconf gtkglext)
makedepends=(libtool mesa xulrunner pkgconfig boost git)
provides=(gnash-common gnash-gtk)
conflicts=(gnash-common gnash-gtk)
replaces=(gnash-common gnash-gtk)
options=(!emptydirs)
backup=(etc/gnashrc etc/gnashthumbnailrc etc/gnashpluginrc)
install=gnash-gtk.install
source=('gnash::git://git.sv.gnu.org/gnash.git#commit=a3180f2'
nodebug.patch)
sha256sums=('SKIP'
'0ebb104a7632af997c7e6b268755949fa0c1eea5e32015b95a22d63d0e431551')
prepare() {
cd gnash
# Disable very, very verbose debugging (gigabytes of logs)
patch -Np1 -i ../nodebug.patch
./autogen.sh
}
build() {
cd gnash
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--with-plugins-install=system \
--with-npapi-plugindir=/usr/lib/mozilla/plugins \
--enable-gui=sdl,gtk,dump \
--enable-media=ffmpeg \
--enable-renderer=all \
--enable-device=x11
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' -e 's/ if test "$export_dynamic" = yes && test -n "$export_dynamic_flag_spec"; then/ func_append compile_command " -Wl,-O1,--as-needed"\n func_append finalize_command " -Wl,-O1,--as-needed"\n\0/' libtool
make
}
package() {
cd gnash
make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="$pkgdir" install install-plugin
install -m755 -d "$pkgdir/usr/share/gconf/schemas"
gconf-merge-schema "$pkgdir/usr/share/gconf/schemas/gnash.schemas" --domain gnash \
"$pkgdir"/usr/share/applications/*.schemas
rm -f "$pkgdir"/usr/share/applications/*.schemas
}
|
