blob: a52b25fd2783306b24f7319ccaef35ee4339a41d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Maintainer: Tim Van den Langenbergh <tmt_vdl@gmx.com>
# Contributor: Omar Botta <omarbotta@gnulinuxlibre.net>
# Contributor: Carlos Sanchez <cargabsj175@vegnux.org.ve>
# Contributor: Frederic Bezies <fredbezies@gmail.com>
pkgname=gnash-git
_gitname=gnash
pkgver=0.8.11.r22270.g84f8bfd
pkgrel=1.1
pkgdesc="The GNU SWF Player based on GameSWF - git development version"
arch=('i686' 'x86_64')
url="http://www.gnu.org/software/gnash/"
license=('GPL3')
depends=('curl' 'giflib' 'sdl' 'libjpeg' 'libpng' 'libltdl' 'libgl'
'glu' 'speex' 'fontconfig' 'cairo' 'ffmpeg' 'jemalloc' 'boost-libs'
'gtk2' 'libldap' 'hicolor-icon-theme' 'desktop-file-utils' 'gconf'
'gtkglext' 'agg')
makedepends=('mesa' 'xulrunner' 'pkgconfig' 'boost' 'git')
provides=('gnash-common' 'gnash-gtk')
conflicts=('gnash-common' 'gnash-gtk')
replaces=('gnash-common' 'gnash-gtk')
options=('!emptydirs')
install=$_gitname.install
backup=('etc/gnashpluginrc')
source=("libre://$pkgname-$pkgver.tar.gz")
md5sums=('efe95a81cc3bc4316f5d3567d821d15d')
mksource=('git://git.sv.gnu.org/gnash.git')
mkmd5sums=('SKIP')
pkgver() {
cd $_gitname
echo "0.8.11.r$(git rev-list --count master).g$(git log -1 --format="%h")"
}
prepare() {
cd $_gitname
chmod +x autogen.sh
./autogen.sh
}
build() {
cd $_gitname
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--with-plugins-install=system \
--with-npapi-plugindir=/usr/lib/mozilla/plugins \
--enable-gui=sdl,gtk \
--enable-media=ffmpeg \
--enable-renderer=all \
--enable-device=x11
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' -e 's/ if test "$export_dynamic" = yes && test -n "$export_dynamic_flag_spec"; then/ func_append compile_command " -Wl,-O1,--as-needed"\n func_append finalize_command " -Wl,-O1,--as-needed"\n\0/' libtool
make
}
package() {
cd $_gitname
make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="$pkgdir" install install-plugin
install -m755 -d "$pkgdir/usr/share/gconf/schemas"
gconf-merge-schema "$pkgdir/usr/share/gconf/schemas/gnash.schemas" --domain gnash \
"$pkgdir"/usr/share/applications/*.schemas
rm -f "$pkgdir"/usr/share/applications/*.schemas
}
|
