blob: 2a160eab6339a59e843ddad8fd6d8d35c5897683 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# Maintainer (aur): Andrea Feletto <andrea@andreafeletto.com>
# Maintainer: Wael Karram <wael@waelk.tech>
# Contributor: bill-auger <bill-auger@programmer.net>
# parabola changes and rationale:
# - delete unlicensed files
pkgname=gmid
pkgver=1.8.3
pkgrel=2
pkgdesc='Fast Gemini server written with security in mind.'
arch=('x86_64')
arch+=('i686' 'armv7h')
url='https://gmid.omarpolo.com'
license=('custom:ISC')
install=${pkgname}.install
backup=(etc/conf.d/${pkgname}
etc/${pkgname}.conf)
depends=('libretls' 'libevent')
mksource=(https://github.com/omar-polo/${pkgname}/releases/download/${pkgver}/${pkgname}-${pkgver}.tar.gz)
source=(
https://repo.parabola.nu/other/${pkgname}-libre/${pkgname}-libre-${pkgver}.tar.xz{,.sig}
"gmid.service"
"gmid.sysusers"
"gmid.confd"
"gmid.initd"
"gmid.conf"
"index.gmi"
)
mksha256sums=('f7b6cc1deaea6c5242301fa7440c0f5caaf282fea780ba1edcef480f7fa67fe1')
sha256sums=(
'5a7ad3ef93434b8a42f18bffe93444de9d30360e4c799dcadac844374e2046ca'
'SKIP'
'946de0766343225068a0e3f38cb39a4a93ef312525dd775226b938cd08706b94'
'4d943727a57dbf5f246963c0f90ccc54919cc2296538457e6b16f29f7580d9d6'
'eddbe93741d01077426bc0239db42815c75a0da5191b4e6528df60ae3e0e5bb3'
'3da15797a8771831b950b246dcd4782a58db68be10fbbc519dbbc758dd336a94'
'2e2b001ee1dc9d42def2d3f68fbe900f1043244c4c3402b15f54d9e091ff9a7e'
'bea228ba92a03b5f0462f54bac69a47f7d063c08830a7721503b7841da6845c0'
)
validpgpkeys=('3954A7AB837D0EA9CFA9798925DB7D9B5A8D4B40') # bill-auger
mksource() {
cd "$srcdir/$pkgname-$pkgver"
# Remove unlicensed files.
rm -r contrib
rm -r site
}
build() {
cd "$srcdir/$pkgname-$pkgver"
MANDIR='usr/share/man/' ./configure --prefix='usr/'
make
}
package() {
# Install the config and service files.
cd "$srcdir"
install -Dm644 gmid.service -t "$pkgdir/usr/lib/systemd/system"
install -Dm644 gmid.sysusers -t "$pkgdir/usr/lib/sysusers.d"
install -Dm644 gmid.confd "$pkgdir/etc/conf.d/gmid"
install -Dm755 gmid.initd "$pkgdir/etc/init.d/gmid"
install -Dm644 gmid.conf "$pkgdir/etc/gmid.conf"
# Install the program files.
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir/" install
# Install the documentation files.
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
install -Dm644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
install -Dm644 ../index.gmi "$pkgdir/usr/share/doc/$pkgname/index.gmi"
}
|
