blob: 41fe2bd276ba8c04cf258113e14775832ccd6283 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Maintainer: Márcio Silva <coadde@parabola.nu>
# based of gegl
_pkgname=gegl
pkgname=gegl-devel
pkgver=0.3.10
pkgrel=1
pkgdesc="Graph based image processing framework"
arch=('i686' 'x86_64' 'armv7h')
url="http://www.gegl.org/"
license=('GPL3' 'LGPL3')
depends=('babl-devel' 'libspiro' 'json-glib')
makedepends=('intltool' 'ruby' 'lua' 'libraw' 'openexr' 'mesa' 'glu' 'ffmpeg' 'librsvg'
'jasper' 'libtiff' 'exiv2' 'vala' 'python2' 'suitesparse' 'lensfun'
'gobject-introspection' 'git')
optdepends=('libraw: raw plugin'
'openexr: openexr plugin'
'ffmpeg: ffmpeg plugin'
'suitesparse: matting-levin plugin'
'librsvg: svg plugin'
'jasper: jasper plugin'
'libtiff: tiff plugin'
'lua: lua plugin'
'lensfun: lens-correct plugin')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("git://git.gnome.org/gegl#tag=GEGL_${pkgver//./_}")
sha256sums=('SKIP')
prepare() {
mkdir path
ln -s /usr/bin/python2 path/python
cd ${_pkgname}
NOCONFIGURE=1 ./autogen.sh
}
build() {
export PATH="$srcdir/path:$PATH" PYTHON=/usr/bin/python2
cd ${_pkgname}
./configure --prefix=/usr --with-sdl --with-librsvg \
--with-libavformat --with-jasper --disable-docs \
--enable-workshop
# https://bugzilla.gnome.org/show_bug.cgi?id=655517
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
check() {
export PATH="$srcdir/path:$PATH" PYTHON=/usr/bin/python2
cd ${_pkgname}
make -k check || :
}
package() {
export PATH="$srcdir/path:$PATH" PYTHON=/usr/bin/python2
cd ${_pkgname}
make DESTDIR="${pkgdir}" install
}
|
