pcr-testing/qt5-styleplugins/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: bill-auger <bill-auger@programmer.net>
# Contributor: Felix Yan <felixonmars@archlinux.org>
# Contributor: Eli Schwartz <eschwartz@archlinux.org>

pkgname=(qt5-styleplugins)
pkgver=5.0.0.20170311
_commit=335dbece103e2cbf6c7cf819ab6672c2956b17b3
pkgdesc='Additional style plugins for Qt5'
pkgrel=22
arch=(armv7h i686 x86_64)
url=https://github.com/qt/qtstyleplugins
license=('LGPL')
depends=('qt5-base' 'gtk2')
source=(${pkgname}-${_commit}.tar.gz::${url}/archive/${_commit}.tar.gz
        qt-5.15-fix.patch)
sha512sums=('e8c2d0e9c6b0a47cab04ffd2e9384606638905b63a7c1580f9b629bbcc84ebff19743363ffee3dbd31c3de1dcda684211ad3052932b5aa0081e529afd9cbb14d'
            '5295895bed83dc1a7756282b3e1d7ad34ea368dd51695c4da4a1ba857083c374e968378b3fb00216b8afce77dd0ba0659ff4b342bd313e67d446b7fbdfb60913')
install='install.sh'


prepare() {
    cd qtstyleplugins-${_commit}

    patch -p1 < "${srcdir}"/qt-5.15-fix.patch
}

build() {
    cd qtstyleplugins-${_commit}

    qmake PREFIX='/usr' \
          CONFIG+='nostrip' \
          QMAKE_CFLAGS_RELEASE="$CFLAGS" \
          QMAKE_CXXFLAGS_RELEASE="$CXXFLAGS"
    make
}

package() {
    cd qtstyleplugins-${_commit}

    make INSTALL_ROOT="${pkgdir}" install
}