nonsystemd/your-initfreedom/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30

# Maintainer: Parabola Project <dev@lists.parabola.nu>

pkgname=your-initfreedom
pkgdesc="This package conflicts with every package known to work only for/with systemd."
license=('GPL3')
url="https://git.parabola.nu/blacklist.git"
pkgver=20220719
_gitver=daf9eebc77cc719c818165e256efd5e0d5dee7aa
pkgrel=1

arch=('any')
install="${pkgname}.install"

makedepends=(librelib)
source=("blacklist-${_gitver}.txt::https://git.parabola.nu/blacklist.git/plain/${pkgname}-blacklist.txt?id=${_gitver}")
sha512sums=('0060ebc516b1aee1149186e53a1c665d6790da2db7e43ade136731c8b5bd7ab24c4ce9431af8c5a06f3ad569ab73bcd2e5ff0179ac3c8f332ae78fdc266addeb')

package() {
	cd "$srcdir"

	conflicts=($( \
		< blacklist-${_gitver}.txt \
		libreblacklist normalize | \
		cut -d: -f1,2 | \
		sed -n 's/:$//p' | \
		sort -u \
		))

	install -Dm644 blacklist-${_gitver}.txt "$pkgdir"/usr/share/doc/${pkgname}/blacklist.txt
}