nonsystemd/your-initfreedom/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35

# Maintainer: Parabola Project <dev@lists.parabola.nu>

pkgname=your-initfreedom
pkgdesc="This package will remove support for systemd."
license=('GPL3')
url="https://git.parabola.nu/blacklist.git"
pkgver=20180727
_gitver=bec14101e3bc6ea6a977fc6e90072d44d5baf1b8
pkgrel=1

arch=('any')
groups=('base-openrc')
install=${pkgname}.install

makedepends=(librelib)
source=(blacklist-${_gitver}.txt::https://git.parabola.nu/blacklist.git/plain/${pkgname}-blacklist.txt?id=${_gitver})
sha512sums=('b1bb29cdcc6c66aead1c435571b316e38322f06943448baad94310d25512664a7b849e92267e401f14cc1f40f06e015b0e670a06e1f85536dbba6442634be2b6')

pkgver() {
    date +%Y%m%d
}

package() {
	cd "$srcdir"

	conflicts=($(
		< blacklist-${_gitver}.txt \
		libreblacklist normalize |
		cut -d: -f1,2 |
		sed -n 's/:$//p' |
		sort -u
		))

	install -Dm644 blacklist-${_gitver}.txt "$pkgdir"/usr/share/doc/${pkgname}/blacklist.txt
}