blob: 6303ef3a69c832572d5080bfbf2c22458409c826 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Maintainer: David P. <megver83@parabola.nu>
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
pkgname=sddm
pkgver=0.19.0
pkgrel=8
pkgrel+=.nonsystemd1
pkgdesc='QML based X11 and Wayland display manager'
arch=(x86_64)
arch+=(i686 armv7h)
url='https://github.com/sddm/sddm'
license=(GPL)
depends=(qt5-declarative xorg-xauth xorg-server ttf-font)
makedepends=(extra-cmake-modules python-docutils qt5-tools)
backup=('usr/share/sddm/scripts/Xsetup'
'usr/share/sddm/scripts/Xstop'
'etc/pam.d/sddm'
'etc/pam.d/sddm-autologin'
'etc/pam.d/sddm-greeter')
provides=(display-manager)
source=($pkgname-$pkgver.tar.gz::"https://github.com/$pkgname/$pkgname/archive/v$pkgver.tar.gz"
sddm.sysusers sddm.tmpfiles
pam-faillock.patch
sddm-fix-race-pre.patch::"https://github.com/sddm/sddm/commit/68cc9e31.patch"
sddm-fix-race.patch::"https://patch-diff.githubusercontent.com/raw/sddm/sddm/pull/1324.patch"
sddm-desktop-session.patch::"https://github.com/sddm/sddm/commit/5fd5ed27.patch"
sddm-0.18.0-Xsession.patch
sddm-0.19.0-pam-1.4-substack.patch
sddm-0.19.0-Xserver_startup.patch
sddm-fix-build.patch)
sha256sums=('e76da1f13d5ad5e0179e3fec57543126044339405ef19c397e105e0807bd4e41'
'9fce66f325d170c61caed57816f4bc72e9591df083e89da114a3bb16b0a0e60f'
'db625f2a3649d6d203e1e1b187a054d5c6263cadf7edd824774d8ace52219677'
'441f441fc63c16c5dbd83411a305d88b17e50836c958677db881b9b6c13c668a'
'33770560315b5369fd15baf5cd877f1191e642cefc6d2a1b4f0a7a80c109c025'
'bbe45a316140c145d7de67dbe95764e44a0787ad9c6bcd2f7e0694484bd79640'
'83e4df6e1c0c23e7b38c1d523c236108eae177ba11c5d466825690845ef99fcf'
'dc2384e1b17cf1a217bff363c948494a74ec8d41c2a11dbd3cec0aefa880e845'
'921674946b1d0f728382ebd4fde2566f16b80434ebce6e790c684f98819273bb'
'd46932e0a60cf5050aaea590ff5f3ab580d2118cbf746f55f78033f72f1bcb76'
'e9058d261138e637248b20243e3e81ff337ab669a4a25fbff387bf9558a682c6')
options=(debug)
prepare() {
patch -d $pkgname-$pkgver -p1 < pam-faillock.patch # Port away from deprecated pam_tally2
patch -d $pkgname-$pkgver -p1 < sddm-fix-race-pre.patch # Make next patch apply
patch -d $pkgname-$pkgver -p1 < sddm-fix-race.patch # Fix race at startup
patch -d $pkgname-$pkgver -p1 < sddm-desktop-session.patch # Fix desktop session name
patch -d $pkgname-$pkgver -p1 < sddm-fix-build.patch # Fix build with Qt post 5.15.2
}
build() {
cmake -B build -S $pkgname-$pkgver \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBEXECDIR=/usr/lib/sddm \
-DDBUS_CONFIG_DIR=/usr/share/dbus-1/system.d \
-DDBUS_CONFIG_FILENAME=sddm_org.freedesktop.DisplayManager.conf \
-DUSE_ELOGIND=yes \
-DNO_SYSTEMD=yes \
-DBUILD_MAN_PAGES=ON \
-DUID_MAX=60513
cmake --build build
}
package() {
DESTDIR="$pkgdir" cmake --install build
install -Dm644 sddm.sysusers "$pkgdir"/usr/lib/sysusers.d/sddm.conf
install -Dm644 sddm.tmpfiles "$pkgdir"/usr/lib/tmpfiles.d/sddm.conf
install -d "$pkgdir"/usr/lib/sddm/sddm.conf.d
"$pkgdir"/usr/bin/sddm --example-config > "$pkgdir"/usr/lib/sddm/sddm.conf.d/default.conf
# Don't set PATH in sddm.conf
sed -r 's|DefaultPath=.*|DefaultPath=/usr/local/sbin:/usr/local/bin:/usr/bin|g' -i "$pkgdir"/usr/lib/sddm/sddm.conf.d/default.conf
# Unset InputMethod https://github.com/sddm/sddm/issues/952
sed -e "/^InputMethod/s/qtvirtualkeyboard//" -i "$pkgdir"/usr/lib/sddm/sddm.conf.d/default.conf
}
|
