blob: 565beb0e69699ea8d11c91bae88809f43600db4c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
|
# Maintainer: David P. <megver83@parabola.nu>
# Maintainer (Arch): Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor (Arch): Jan de Groot <jgc@archlinux.org>
# Contributor (Arch): Tom Gundersen <teg@jklm.no>
# Contributor (Arch): Link Dupont <link@subpop.net>
pkgname=dbus
pkgver=1.12.20
pkgrel=1
pkgrel+=.nonsystemd2
pkgdesc="Freedesktop.org message bus system"
url="https://wiki.freedesktop.org/www/Software/dbus/"
arch=(x86_64)
arch+=(i686 armv7h)
license=(GPL custom)
depends=(libx11 libelogind expat audit)
depends+=(libelogind.so libaudit.so)
makedepends=(elogind xmlto docbook-xsl python yelp-tools doxygen git autoconf-archive)
provides=(libdbus libdbus-1.so)
provides+=(dbus-elogind dbus-openrc)
conflicts=(libdbus dbus-elogind dbus-openrc)
replaces=(${conflicts[@]})
source=("git+https://gitlab.freedesktop.org/dbus/dbus.git?signed#tag=dbus-$pkgver"
dbus-enable-elogind.patch
no-fatal-warnings.diff
dbus-reload.hook
dbus.initd)
sha256sums=('SKIP'
'faffcaa5b295f49fcedeed2c9ece5298949096be3062fd99a4bf1a6ac3ad1ea0'
'6958eeec07557b92a28419eb1702331ee2f0a6fd17285e37dfb6130b9fa4cf6e'
'1335a86bb5eb68614bf13af314f1a7f5f6f68253584986e9c5b492a4585ab722'
'9964aa935b4a7d64f5970bcfcd561b06013a85ae2712444bc4c5f644364dab3b')
validpgpkeys=('DA98F25C0871C49A59EAFF2C4DE8FF2A63C7CC90') # Simon McVittie <simon.mcvittie@collabora.co.uk>
prepare() {
cd dbus
patch -Np 1 -i ../dbus-enable-elogind.patch
# Allow us to enable checks without them being fatal
patch -Np1 -i ../no-fatal-warnings.diff
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd dbus
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--libexecdir=/usr/lib/dbus-1.0 \
--with-console-auth-dir=/run/console/ \
--with-dbus-user=dbus \
--with-system-pid-file=/run/dbus/pid \
--with-system-socket=/run/dbus/system_bus_socket \
--without-systemdsystemunitdir \
--enable-inotify \
--enable-libaudit \
--disable-systemd \
--disable-user-session \
--enable-xml-docs \
--enable-doxygen-docs \
--enable-ducktype-docs \
--disable-static \
--enable-elogind \
--enable-x11-autolaunch
make
}
check() {
make -C dbus check
}
package() {
DESTDIR="$pkgdir" make -C dbus install
rm -r "$pkgdir"/{etc,var}
# We have a pre-assigned uid (81)
echo 'u dbus 81 "System Message Bus"' |
install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/dbus.conf"
install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 dbus/COPYING
# Remove docs
rm -r "$pkgdir/usr/share/doc"
# Init script
install -Dt "$pkgdir/usr/share/libalpm/hooks" -m644 *.hook
install -Dm755 "$srcdir/dbus.initd" "$pkgdir/etc/init.d/dbus"
install -d "${pkgdir}/etc/runlevels/default"
ln -sf "/etc/init.d/dbus" "${pkgdir}/etc/runlevels/default/dbus"
}
|
