blob: 1aa3d8646a42ed87ef5d8952d98762764b543fff (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
# $Id$
# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor (Arch): Daniel J Griffiths <ghost1227@archlinux.us>
# Contributor (Arch): Corrado Primier <bardo@aur.archlinux.org>
# Contributor (Arch): William Rea <sillywilly@gmail.com>
# Maintainer: David P. <megver83@parabola.nu>
_pkgbasename=libpulse
pkgname=lib32-$_pkgbasename
pkgdesc="A featureful, general-purpose sound server (32-bit client libraries)"
pkgver=11.1
pkgrel=1
pkgrel+=.nonsystemd1
arch=(x86_64)
url="https://www.freedesktop.org/wiki/Software/PulseAudio/"
license=(LGPL)
depends=(lib32-dbus lib32-glib2 lib32-eudev
lib32-libasyncns lib32-libcap lib32-libxtst lib32-libsm lib32-libsndfile
$_pkgbasename)
makedepends=(libtool intltool lib32-speexdsp lib32-gtk3 git lib32-libltdl)
optdepends=('lib32-alsa-plugins: ALSA support')
provides=("lib32-pulseaudio=$pkgver")
conflicts=(lib32-pulseaudio)
replaces=(lib32-pulseaudio)
options=(!emptydirs)
_commit=f93e372b0b2cb960df04de3f0a8fbea683bb8229 # tags/v11.1^0
source=("git+https://anongit.freedesktop.org/git/pulseaudio/pulseaudio#commit=$_commit")
sha256sums=('SKIP')
_pulsever=$pkgver
[[ $_pulsever = *.*.* ]] && _pulsever=${_pulsever%.*}
_libs="libpulse.la libpulse-simple.la libpulse-mainloop-glib.la"
_pkglibs="libpulsecommon-${_pulsever}.la libpulsedsp.la"
pkgver() {
cd pulseaudio
git describe --tags | sed 's/^v//;s/-/+/g'
}
prepare() {
cd pulseaudio
NOCONFIGURE=1 ./bootstrap.sh
}
build() {
cd pulseaudio
export CC="gcc -m32"
export CXX="g++ -m32"
export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
./configure --prefix=/usr \
--libdir=/usr/lib32 \
--sysconfdir=/etc \
--libexecdir=/usr/lib32 \
--localstatedir=/var \
--disable-tcpwrap \
--disable-bluez4 \
--disable-samplerate \
--disable-rpath \
--disable-default-build-tests \
--with-systemduserunitdir=no \
--enable-systemd-login=no \
DATADIRNAME=share
# fight unused direct deps
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make -C src $_libs $_pkglibs
}
package() {
cd pulseaudio
make -j1 -C src DESTDIR="$pkgdir" \
lib_LTLIBRARIES="$_libs" install-libLTLIBRARIES
make -j1 -C src DESTDIR="$pkgdir" \
pkglib_LTLIBRARIES="$_pkglibs" install-pkglibLTLIBRARIES
make -j1 DESTDIR="$pkgdir" install-pkgconfigDATA
}
|
