nonprism/kdenetwork-kopete-libre-nonprism/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

# $Id: PKGBUILD 201659 2013-12-17 13:52:43Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>

_pkgname=kdenetwork-kopete
pkgname=kdenetwork-kopete-libre-nonprism
pkgver=4.12.0
pkgrel=1
pkgdesc='Instant Messenger, without skype and support for unsafe and dangerous for privacy protocols'
url='http://kde.org/applications/internet/kopete/'
arch=('i686' 'x86_64' 'mips64el')
license=('GPL' 'LGPL' 'FDL')
groups=('kde' 'kdenetwork')
depends=('kdebase-runtime' 'kdepimlibs' 'qca-ossl' 'libotr' 'libidn'
         'qimageblitz' 'mediastreamer' 'jsoncpp')
makedepends=('cmake' 'automoc4' 'boost')
install=${_pkgname}.install
replaces=$_pkgname
conflicts=$_pkgname
provides=$_pkgname=$pkgver
source=("http://download.kde.org/stable/${pkgver}/src/kopete-${pkgver}.tar.xz"
        'libre-nonprism.patch')
sha1sums=('c1ef611b27079388e48e558a65e2de80db93d875'
          'ddde6ed0b6f281512dc12cb80f712f33c6932c92')

prepare() {
  cd kopete-${pkgver}
  # Based on http://bzr.trisquel.info/package-helpers/trunk/annotate/head%3A/helpers/natty/make-kdenetwork, revision 34.
  sed -i 's/Skype protocol" ON/Skype protocol" OFF/g' protocols/CMakeLists.txt
  rm -rf protocols/skype
  # remove unsafe/dangerous services
  sed -i 's/Oscar (ICQ and AIM) protocol" ON/Oscar (ICQ and AIM) protocol" OFF/g' protocols/CMakeLists.txt
  rm -rf protocols/oscar
  sed -i 's/Yahoo protocol" ON/Yahoo protocol" OFF/g' protocols/CMakeLists.txt
  rm -rf protocols/yahoo
  sed -i 's/QQ protocol" ON/QQ protocol" OFF/g' protocols/CMakeLists.txt
  rm -rf protocols/qq
  sed -i 's/Novell GroupWise Messenger protocol" ON/Novell GroupWise Messenger protocol" OFF/g' protocols/CMakeLists.txt
  rm -rf protocols/groupwise
  sed -i 's/Gadu-Gadu protocol" ON/Gadu-Gadu protocol" OFF/g' protocols/CMakeLists.txt
  rm -rf protocols/gadu
  sed -i 's/Google Talk support" ON/Google Talk support" OFF/g' protocols/CMakeLists.txt
  sed -i 's/Window Live Messenger support" ON/Window Live Messenger support" OFF/g' protocols/CMakeLists.txt
  rm -rf protocols/wlm
  sed -i 's/Windows Live Messenger voice clip support" ON/Windows Live Messenger voice clip support" OFF/g' protocols/CMakeLists.txt
  sed -i 's/meanwhile protocol" ON/meanwhile protocol" OFF/g' protocols/CMakeLists.txt
  rm -rf protocols/meanwhile
  patch -p1 -i "${srcdir}"/libre-nonprism.patch
  cd ..
  mkdir build
}

build() {
  cd build
  cmake ../kopete-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DKDE4_BUILD_TESTS=OFF \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_SKIP_RPATH=ON
  make
}

package() {
  cd build
  make DESTDIR=$pkgdir install
}