blob: d6a9dc5486b52f30e6dae2f1da8b86bb57e4b4b7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer: Márcio Silva <coadde@hyperbola.info>
# Contributor: Isaac David <isacdaavid@at@isacdaavid@dot@info>
pkgname=evolution-data-server
pkgver=3.24.4
pkgrel=1.nonprism1
pkgdesc="Centralized access to appointments and contacts, without libgdata support"
url="https://wiki.gnome.org/Apps/Evolution"
arch=(i686 x86_64)
depends=(gnome-online-accounts nss krb5 libgweather libical db libphonenumber)
makedepends=(intltool gperf gobject-introspection vala gtk-doc boost git cmake ninja)
license=(GPL)
replaces=("${pkgname}-coherence" "${pkgname}-nonprism")
conflicts=("${pkgname}-coherence" "${pkgname}-nonprism")
_commit=4b64d44b1dd01a05be38504ae2a130f21a417913 # tags/EVOLUTION_DATA_SERVER_3_24_4^0
source=("git+https://git.gnome.org/browse/evolution-data-server#commit=$_commit")
sha256sums=('SKIP')
pkgver() {
cd $pkgname
git describe --tags | sed 's/^EVOLUTION_DATA_SERVER_//;s/_/./g;s/-/+/g'
}
build() {
cd $pkgname
cmake . -G Ninja \
-DCMAKE_INSTALL_PREFIX=/usr \
-DLIBEXEC_INSTALL_DIR=/usr/lib/$pkgname \
-DSYSCONF_INSTALL_DIR=/etc \
-DENABLE_INTROSPECTION=ON \
-DENABLE_VALA_BINDINGS=ON \
-DENABLE_UOA=OFF \
-DENABLE_GOOGLE=OFF \
-DHAVE_LIBGDATA=OFF \
-DENABLE_GOOGLE_AUTH=OFF \
-DENABLE_GTK_DOC=ON \
-DWITH_PHONENUMBER=ON
ninja
}
check() {
cd $pkgname
# libedata-book tests fail because they try to
# mkdir /usr/lib/evolution-data-server/camel-providers
ninja test || :
}
package() {
cd $pkgname
DESTDIR="$pkgdir" ninja install
}
|
