blob: 1196644840cc3a56ce8c2c502d080cee6c01cbec (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# $Id: PKGBUILD 285531 2017-01-07 15:36:43Z heftig $
# Maintainer (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer: Márcio Silva <coadde@parabola.nu>
pkgname=evolution-data-server
pkgver=3.22.3
pkgrel=2.nonprism1
pkgdesc="Centralized access to appointments and contacts, without libgdata support"
url="https://wiki.gnome.org/Apps/Evolution"
arch=(i686 x86_64)
depends=(gnome-online-accounts nss krb5 libgweather libical db libphonenumber)
makedepends=(intltool gperf gobject-introspection vala gtk-doc boost git gnome-common)
license=(GPL)
replaces=("${pkgname}-coherence" "${pkgname}-nonprism")
conflicts=("${pkgname}-coherence" "${pkgname}-nonprism")
_commit=9d0d40d02034e37b6589f463f4e2a07fc6e5a782 # tags/EVOLUTION_DATA_SERVER_3_22_3^0
source=("git+https://git.gnome.org/browse/evolution-data-server#commit=$_commit")
sha256sums=('SKIP')
pkgver() {
cd $pkgname
git describe --tags | sed 's/^EVOLUTION_DATA_SERVER_//;s/_/./g;s/-/+/g'
}
prepare() {
cd $pkgname
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd $pkgname
./configure --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --with-openldap=yes \
--libexecdir=/usr/lib/evolution-data-server \
--with-krb5=/usr --with-libdb=/usr --with-phonenumber=/usr \
--without-libgdata \
--disable-google \
--enable-vala-bindings --disable-uoa \
--enable-gtk-doc
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
check() {
cd $pkgname
# libedata-book tests fail because they try to
# mkdir /usr/lib/evolution-data-server/camel-providers
make check -k || :
}
package() {
cd $pkgname
make DESTDIR="$pkgdir" install
}
|
