blob: 21dfe9a479c69adc8b7cc44361691ad9173cdfc0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# $Id: PKGBUILD 110919 2014-05-09 15:34:16Z lfleischer $
# Maintainer: Lukas Fleischer <archlinux at cryptocrack dot de>
# Contributor: Kaiting Chen <kaitocracy@gmail.com>
# Contributor: Aaron Schaefer <aaron@elasticdog.com>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>
_pkgname=duplicity
pkgname=duplicity-nonprism
pkgver=0.6.24
pkgrel=1
pkgdesc='A utility for encrypted, bandwidth-efficient backups using the rsync algorithm, without python2-gdata recommendation'
arch=('i686' 'x86_64')
url='http://www.nongnu.org/duplicity/'
license=('GPL')
replaces=$_pkgname
conflicts=$_pkgname
provides=$_pkgname=$pkgver
depends=('gnupg' 'librsync' 'ncftp' 'python2-paramiko' 'python2-lockfile')
makedepends=('python2-setuptools')
optdepends=('lftp: FTPS backend'
'python2-boto: Amazon S3 backend'
'python2-gobject: GIO backend'
'gvfs: GIO backend'
'python2-httplib2: Ubuntu One backend'
'python2-oauthlib: Ubuntu One backend'
'rsync: rsync backend')
source=("https://launchpad.net/$_pkgname/0.6-series/$pkgver/+download/$_pkgname-$pkgver.tar.gz"{,.sig})
md5sums=('5d4e9329a6d793880909d18b0736ff06'
'SKIP')
build() {
cd "${srcdir}/${_pkgname}-${pkgver}"
# python2 fix
for file in $(find . -name '*.py' -print); do
sed -i 's_^#!.*/usr/bin/python$_#!/usr/bin/python2_' $file
sed -i 's_^#!.*/usr/bin/env.*python$_#!/usr/bin/env python2_' $file
done
}
package() {
cd "${srcdir}/${_pkgname}-${pkgver}"
python2 setup.py install --root="$pkgdir" --optimize=1
# fix broken documentation permissions until upstream does (FS#27301)
chmod 644 "$pkgdir/usr/share/man/man1/$_pkgname.1"
chmod 644 "$pkgdir/usr/share/man/man1/rdiffdir.1"
chmod 644 "$pkgdir/usr/share/doc/$_pkgname-$pkgver"/*
}
|
