summaryrefslogtreecommitdiff
path: root/libre/your-freedom/PKGBUILD
blob: ddcf6b3089bbd38da7dc3b8217981a4b392a02e4 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
# Maintainer: Parabola Project <dev@lists.parabola.nu>

pkgname=your-freedom
pkgdesc="This package conflicts with every nonfree package known to date to ensure your system is free."
license=('GPL3')
url="https://git.parabola.nu/blacklist.git"
pkgver=20201003.1
_gitver=987346fa895ccb9faf38f51d72771a743cf6240b
pkgrel=1

arch=('any')
install=${pkgname}.install

makedepends=(librelib)
source=(blacklist-${_gitver}.txt::https://git.parabola.nu/blacklist.git/plain/blacklist.txt?id=${_gitver})
sha512sums=('58afdd099355050a789046db4ba95296a1183abcbe3107ba04eb15c8c8038aa633b313a1fbdee66a6075843e0fa9ff4b5884db0ed94182887475846151d2bc91')

package() {
	cd "$srcdir"

	conflicts=($( \
		< blacklist-${_gitver}.txt \
		libreblacklist normalize | \
		cut -d: -f1,2 | \
		sed -n 's/:$//p' | \
		sort -u \
		))

	install -Dm644 blacklist-${_gitver}.txt "$pkgdir"/usr/share/doc/${pkgname}/blacklist.txt
}