blob: a234da964413a8ac1886395c8bf5623eb08107c8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# $Id: PKGBUILD 278485 2016-10-12 11:49:10Z arojas $
# Maintainer (Arch): Eric Bélanger <eric@archlinux.org>
# Maintainer (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
pkgname=xscreensaver
_pkgname=$pkgname-libre
pkgver=5.38
pkgrel=1.parabola1
pkgdesc="Screen saver and locker for the X Window System, without nonfree asm files"
arch=('i686' 'x86_64' 'armv7h')
url="http://www.jwz.org/xscreensaver/"
license=('BSD')
depends=('libglade' 'libxmu' 'glu' 'xorg-appres' 'perl-libwww')
makedepends=('bc' 'intltool' 'libxpm' 'gdm')
optdepends=('gdm: for login manager support')
replaces=("${_pkgname}")
conflicts=("${_pkgname}")
backup=('etc/pam.d/xscreensaver')
mksource=(http://www.jwz.org/xscreensaver/${pkgname}-${pkgver}.tar.gz)
source=(https://repo.parabola.nu/other/${_pkgname}/${_pkgname}-${pkgver}.tar.gz
xscreensaver-add-electricsheep.diff
LICENSE)
mksha1sums=('b4e6b6799e8e244c894db277d6ff2bf5ee48290c')
sha1sums=('0c13447e00875cdbdb65da4bf54f88b4aeac9bb4'
'e8dc57b6471fb3867ee099304ac6bf628351cb98'
'3eedb8b91b13c29df9b1fe5cbb027e1470b802d2')
mksource() {
cd ${pkgname}-${pkgver}
# Deleting dmsc.asm file due which don't have source code supplied
rm -v hacks/images/m6502/dmsc.asm
}
prepare() {
cd ${pkgname}-${pkgver}
patch -p0 -i "${srcdir}/xscreensaver-add-electricsheep.diff"
}
build() {
cd ${pkgname}-${pkgver}
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--libexecdir=/usr/lib --with-x-app-defaults=/usr/share/X11/app-defaults \
--with-pam --with-login-manager --with-gtk --with-gl \
--without-gle --with-pixbuf --with-jpeg
make
}
package() {
cd ${pkgname}-${pkgver}
install -d "${pkgdir}/etc/pam.d"
make install_prefix="${pkgdir}" install
install -D -m644 ../LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
chmod 755 "${pkgdir}/usr/bin/xscreensaver"
echo "NotShowIn=KDE;GNOME;" >> "${pkgdir}/usr/share/applications/xscreensaver-properties.desktop"
}
|
