libre/xorg-fonts-type1-libre/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# $Id: PKGBUILD 150375 2012-02-17 09:54:09Z allan $
# Maintainer (Arch): Jan de Groot <jgc@archlinux.org>

pkgname=xorg-fonts-type1-libre
pkgver=7.4
pkgrel=2
pkgdesc="X.org Type1 fonts, without nonfree fonts"
arch=(any)
license=('custom')
url="http://xorg.freedesktop.org/"
depends=(xorg-fonts-encodings xorg-fonts-alias xorg-font-utils fontconfig)
provides=("xorg-fonts-type1=${pkgver}")
conflicts=('xorg-fonts-type1')
replaces=('xorg-fonts-type1')
install=xfonts.install
source=(${url}/releases/individual/font/font-bitstream-type1-1.0.2.tar.bz2
        ${url}/releases/individual/font/font-xfree86-type1-1.0.3.tar.bz2)
md5sums=('27c55f6a938e7153c59fb551b2f491f9'
         'df934bfc0339322cee73ee3c5460a648')

build() {
  cd "${srcdir}"
  for dir in *; do
    if [ -d "${dir}" ]; then
      pushd "${dir}"
      ./configure --prefix=/usr \
        --with-fontdir=/usr/share/fonts/Type1
      make
      popd
    fi
  done
}

package() {
  cd "${srcdir}"
  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  for dir in *; do
    if [ -d "${dir}" ]; then
      pushd "${dir}"
      make DESTDIR="${pkgdir}" install
      install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.${dir%-*}"
      popd
    fi
  done
  rm -f "${pkgdir}"/usr/share/fonts/Type1/fonts.*
}