blob: 7272a18d3c149201029c3f1edf675596744cb43b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# $Id: PKGBUILD 212497 2017-02-15 05:21:07Z bgyorgy $
# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Contributor (Arch): Alexander Fehr <pizzapunk gmail com>
# Contributor (Arch): Andrew Simmons <andrew.simmons@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>
pkgbase=xarchiver
pkgname=(xarchiver xarchiver-gtk2)
pkgver=0.5.4.10
pkgrel=1.parabola1
pkgdesc="GTK+ frontend to various command line archivers, without nonfree unrar support"
arch=('i686' 'x86_64' 'armv7h')
url="https://github.com/ib/xarchiver"
license=('GPL')
depends=('gtk2' 'gtk3')
makedepends=('docbook-xsl' 'intltool' 'xmlto')
optdepends=('zip: ZIP support'
'unzip: ZIP support'
'p7zip: 7z support'
'lzop: LZOP support'
'cpio: RPM support')
source=($pkgbase-$pkgver.tar.gz::https://github.com/ib/xarchiver/archive/$pkgver.tar.gz
libre.patch)
sha256sums=('bb452d8ef4eabb52ab1313b3867156ea5030b75f9e59c59c7ef487c8db9dbea4'
'07a7cad5f896f37d5b1120e429a7b6fd4acd9fa006d35cd705228b98bc45ddb8')
prepare() {
cd $pkgbase-$pkgver
# Remove nonfree unRAR support
patch -p1 -i ../libre.patch
rm -v src/rar.{c,h}
./autogen.sh
}
build() {
# GTK+ 3 version
[ -d gtk3 ] || cp -r $pkgbase-$pkgver gtk3
cd gtk3
./configure --prefix=/usr --libexecdir=/usr/lib/xfce4
make -j1
cd "$srcdir"
# GTK+ 2 version
[ -d gtk2 ] || cp -r $pkgbase-$pkgver gtk2
cd gtk2
./configure --prefix=/usr --libexecdir=/usr/lib/xfce4 --enable-gtk2
make -j1
}
package_xarchiver() {
depends=('gtk3')
conflicts=('xarchiver-libre')
replaces=('xarchiver-libre')
cd gtk3
make DESTDIR="$pkgdir" install
}
package_xarchiver-gtk2() {
pkgdesc+=' (GTK+ 2 version)'
depends=('gtk2')
conflicts=('xarchiver')
cd gtk2
make DESTDIR="$pkgdir" install
}
|
