blob: b050c52af00f9a55a760353266dbe1c35c345361 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer (Arch): Ray Rashif <schiv@archlinux.org>
# Contributor (Arch): Mateusz Herych <heniekk@gmail.com>
# Contributor (Arch): Charles Lindsay <charles@chaoslizard.org>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Contributor (Hyperbola): Márcio Silva <coadde@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
_basekernel=4.17
_archrel=87
_parabolarel=1
pkgbase=vhba-module
pkgname=(vhba-module vhba-module-dkms)
pkgver=20170610
pkgrel=${_archrel}.parabola${_parabolarel}.basekernel${_basekernel}
pkgdesc="Kernel module that emulates SCSI devices (built for the linux-libre kernel package)"
arch=('i686' 'x86_64' 'armv7h')
url="http://cdemu.sourceforge.net/"
license=('GPL')
# Generic (you shouldn't have to modify any of these variables)
_toohigh=$(IFS=. read a b <<<$_basekernel; echo $a.$((b+1)))
makedepends=("linux-libre-headers>=${_basekernel}" "linux-libre-headers<${_toohigh}" "linux-libre>=${_basekernel}" "linux-libre<${_toohigh}")
makedepends+=('libelf')
_extramodules=extramodules-${_basekernel}
source=("https://downloads.sourceforge.net/cdemu/$pkgbase-$pkgver.tar.bz2"
'60-vhba.rules' 'dkms.conf')
sha256sums=('7970c93f989d9c4f2629371bf5ee7a76f95e4c12342c3320ddc528d0df02d9ec'
'3052cb1cadbdf4bfb0b588bb8ed80691940d8dd63dc5502943d597eaf9f40c3b'
'8cab0ebb4fee72069d63616b0983f105b98d1261e72e9bef5509a6e60bc382a7')
build() {
cd $pkgbase-$pkgver
make KERNELRELEASE="$(cat /usr/lib/modules/$_extramodules/version)"
}
package_vhba-module() {
depends=("linux-libre>=${_basekernel}" "linux-libre<${_toohigh}")
replaces=("${pkgbase}-libre" "${pkgbase}-parabola")
conflicts=("${pkgbase}-libre" "${pkgbase}-parabola")
cd $pkgbase-$pkgver
install -Dt "$pkgdir/usr/lib/modules/$_extramodules" -m644 *.ko
install -Dt "$pkgdir/usr/lib/udev/rules.d" -m644 ../60-vhba.rules
echo 'g cdemu - -' | install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/cdemu.conf"
find "$pkgdir" -name '*.ko' -exec xz {} +
}
package_vhba-module-dkms() {
depends=(dkms)
provides=("vhba-module=$pkgver-$_archrel")
conflicts=(vhba-module)
cd $pkgbase-$pkgver
install -Dt "$pkgdir/usr/src/$pkgbase-$pkgver" -m644 Makefile vhba.c ../dkms.conf
install -Dt "$pkgdir/usr/lib/udev/rules.d" -m644 ../60-vhba.rules
echo 'g cdemu - -' | install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/cdemu.conf"
}
# vim:set ts=2 sw=2 et:
|
