blob: 7f7cc2ca61ede762b38619babb7b43d45048b9aa (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer (Arch): Lukas Fleischer <lfleischer@archlinux.org>
# Contributor (Arch): xduugu
# Contributor (Arch): nh2
# Contributor (Arch): Steven Davidovitz <steviedizzle ð gmail đ com>
# Contributor (Arch): Nick B <Shirakawasuna ð gmail đ com>
# Contributor (Arch): Christof Musik <christof ð senfdax đ de>
# Contributor (Arch): Stefan Rupp <archlinux ð stefanrupp đ de>
# Contributor (Arch): Ignas Anikevicius <anikevicius ð gmail đ com>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Contributor (Hyperbola): Márcio Silva <coadde@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
_basekernel=5.1.4_gnu-1
pkgname=tp_smapi
pkgver=0.43
pkgrel=97
pkgrel+=.parabola1.basekernel${_basekernel%_*}
pkgdesc="Modules for ThinkPad's SMAPI functionality"
pkgdesc+=" (built for the linux-libre kernel package)"
arch=('x86_64')
arch+=('i686')
url='https://github.com/evgeni/tp_smapi'
license=('GPL')
depends=(linux-libre=${_basekernel%-*})
makedepends=(linux-libre-headers=${_basekernel%-*} git libelf)
_extradir=/usr/lib/modules/extramodules
_commit=a63729ab30d85430048f65c37f29188ab484cd52 # tags/tp-smapi/0.43
source=("git+https://github.com/evgeni/tp_smapi#commit=$_commit")
sha256sums=('SKIP')
pkgver() {
cd $pkgname
git describe --tags | sed 's/^tp-smapi\///;s/-/+/g'
}
build() {
cd $pkgname
# https://bugs.archlinux.org/task/54975 (kernel has no _GLOBAL_OFFSET_TABLE_):
# Clear EXTRA_CFLAGS since it defaults to injecting CFLAGS and -fno-plt breaks the modules
make HDAPS=1 KVER="$(<$_extradir/version)" EXTRA_CFLAGS=
}
package() {
cd $pkgname
# install kernel modules
find . -name "*.ko" -exec install -Dt "$pkgdir$_extradir" {} +
# compress kernel modules
find "$pkgdir" -name "*.ko" -exec xz {} +
# load module on startup
echo tp_smapi | install -Dm644 /dev/stdin "$pkgdir/usr/lib/modules-load.d/$pkgname.conf"
}
|
