blob: e3fcce1ab67e64c17a2c6447d025e6571de9121f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# $Id: PKGBUILD 116831 2014-08-04 07:32:08Z tpowa $
# Maintainer (Arch): Lukas Fleischer <archlinux at cryptocrack dot de>
# Contributor (Arch): xduugu
# Contributor (Arch): nh2
# Contributor (Arch): Steven Davidovitz <steviedizzle ð gmail đ com>
# Contributor (Arch): Nick B <Shirakawasuna ð gmail đ com>
# Contributor (Arch): Christof Musik <christof ð senfdax đ de>
# Contributor (Arch): Stefan Rupp <archlinux ð stefanrupp đ de>
# Contributor (Arch): Ignas Anikevicius <anikevicius ð gmail đ com>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: Márcio Silva <coadde@parabola.nu>
# Kernel info
_basekernel=3.16
_kernelname=
# Source info
_pkgname=tp_smapi
pkgver=0.41
pkgdesc="Modules for ThinkPad's SMAPI functionality (built for the linux-libre${_kernelname} kernel package)"
url='https://github.com/evgeni/tp_smapi'
license=('GPL')
source=("https://github.com/downloads/evgeni/${_pkgname}/${_pkgname}-${pkgver}.tar.gz")
md5sums=('63c683415c764568f6bf17c7eabe4752')
# Package info
pkgrel=52
arch=('i686' 'x86_64' 'mips64el')
install='kmod.install'
# Generic (you shouldn't have to modify any of these variables)
pkgname=${_pkgname}-parabola${_kernelname}
_toohigh=$(IFS=. read a b <<<$_basekernel; echo $a.$((b+1)))
_extramodules=extramodules-${_basekernel}${_kernelname}
depends=("linux-libre${_kernelname}>=${_basekernel}" "linux-libre${_kernelname}<${_toohigh}")
makedepends=("linux-libre${_kernelname}-headers>=${_basekernel}" "linux-libre${_kernelname}-headers<${_toohigh}")
replaces=( "${_pkgname}${_kernelname}") # for Arch-compatability
conflicts=("${_pkgname}${_kernelname}") # for Arch-compatability
provides=( "${_pkgname}${_kernelname}=${pkgver}") # for Arch-compatability
if [[ -n "${_kernelname}" ]]; then
provides+=("${_pkgname}-parabola=${pkgver}") # pkgname without _kernelname
fi
build() {
cd "${srcdir}/${_pkgname}-${pkgver}"
_kernver="$(cat /usr/lib/modules/${_extramodules}/version)"
sed -ri -e "s/^(KVER\s*:=).*$/\1 ${_kernver}/" \
-e "s#^(KBASE\s*:=).*\$#\1 /usr/lib/modules/${_kernver}#" Makefile
make HDAPS=1
}
package() {
cd "${srcdir}/${_pkgname}-${pkgver}"
_kernver="$(cat /usr/lib/modules/${_extramodules}/version)"
# Set the correct extramodules directory for install
cp -f "${startdir}/${install}" "${startdir}/${install}.pkg"
true && install=${install}.pkg
sed -r "s/(_extramodules=).*/\1${_extramodules}/" -i "${startdir}/${install}"
# Actually install
make -C "/usr/lib/modules/${_kernver}/build" \
INSTALL_MOD_PATH="${pkgdir}/usr" \
M="${srcdir}/${_pkgname}-${pkgver}" modules_install
cd "${pkgdir}/usr/lib/modules"
mv "${_kernver}/extra" "${_extramodules}"
rmdir "${_kernver}"
# compress kernel modules
find "${pkgdir}" -name "*.ko" -exec gzip -9 {} +
# load module on startup
install -dm 755 "${pkgdir}/usr/lib/modules-load.d"
echo ${_pkgname} > "${pkgdir}/usr/lib/modules-load.d/${pkgname}.conf"
}
|
