blob: 12ced8794b705cd2e9f0656deee59a9966d6223d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer (Arch): Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor (Arch): Ionut Biru <ibiru@archlinux.org>
# Contributor (Arch): Allan McRae <allan@archlinux.org>
# Contributor (Arch): Alessio 'mOLOk' Bolognino <themolok@gmail.com>
# Contributor (Arch): shamrok <szamrok@gmail.com>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Maintainer: André Silva <emulatorman@parabola.nu>
pkgname=smplayer
pkgver=17.4.0
pkgrel=1.parabola1
pkgdesc='Media player with built-in codecs that can play virtually all video and audio formats, without nonfree smtube support'
url='http://smplayer.sourceforge.net/'
arch=('i686' 'x86_64' 'armv7h')
license=('GPL')
depends=('qt5-script' 'mpv' 'hicolor-icon-theme')
makedepends=('qt5-tools')
optdepends=('smplayer-themes: icon themes collection'
'smplayer-skins: skin themes collection'
'youtube-dl: youtube videos and streaming'
'mplayer: alternative multimedia engine')
source=(https://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.bz2
disable-smtube-support.patch
add-missing-QClipboard-include.patch)
sha512sums=('92f5d4e80b189910305f1178efe8939a32b1b0993d41878a2edf042a909e60652a120339aaffa7e244cacffe0ca8506b99f5c9e14a75d6832f94d69338aa77a0'
'813efc30a754015d8bca9391ed3b586481c2cd931a0b234a8cb94cdad7ae92b8976aabd05569099900ce65b8f2fd39d39da0dddff46bfe10891dd5edc4f12283'
'619b8a236b36518bf0f9984d87384d9c5be10fdbda17598d57736064c0c2d6d9f920c9d3f1eb059ba390670ec28559f0dda6f85757ef8696540c424b08863e39')
prepare() {
cd $pkgname-$pkgver
# disable SMTube support
patch -p1 -i $srcdir/disable-smtube-support.patch
# add missing QClipboard include
patch -p1 -i $srcdir/add-missing-QClipboard-include.patch
# fix GNU/Linux name
sed -i 's|Linux|GNU/Linux|' src/smplayer.cpp
}
build() {
cd $pkgname-$pkgver
make PREFIX=/usr \
DOC_PATH="\\\"/usr/share/doc/smplayer\\\"" \
QMAKE_OPTS=DEFINES+=NO_DEBUG_ON_CONSOLE
}
package() {
cd $pkgname-$pkgver
make DOC_PATH=/usr/share/doc/smplayer \
DESTDIR="$pkgdir" PREFIX=/usr install
}
# vim: ts=2 sw=2 et:
|
