blob: fe30cef9f152b31f08df494db1315d31d8d45d2f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# $Id$
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Maintainer (Arch): Maxime Gauduin <alucryd@archlinux.org>
# Contributor (Arch): Themaister <maister@archlinux.us>
# Contributor (Arch): lifning <definelightning@gmail.com>
pkgname=retroarch
pkgver=1.7.3
pkgrel=1.parabola1
pkgdesc='Reference frontend for the libretro API, without nonfree software support, libretro-genesis-plus and libretro-snes9x recommendation'
arch=('x86_64' 'i686' 'armv7h')
url='http://www.libretro.com/'
license=('GPL')
groups=('libretro')
depends=('alsa-lib' 'gcc-libs' 'glibc' 'libdrm' 'libgl' 'libpulse' 'libx11'
'libxcb' 'libxext' 'libxinerama' 'libxkbcommon' 'libxv' 'libxxf86vm'
'mesa' 'openal' 'qt5-base' 'sdl2' 'v4l-utils' 'wayland' 'zlib'
'libass.so' 'libavcodec.so' 'libavformat.so' 'libavutil.so'
'libfreetype.so' 'libswresample.so' 'libswscale.so' 'libudev.so'
'libusb-1.0.so')
makedepends=('vulkan-icd-loader')
optdepends=('libretro-overlays: Collection of overlays'
'libretro-shaders: Collection of shaders'
'python: retroarch-cg2glsl'
'retroarch-assets-xmb: XMB menu assets')
backup=('etc/retroarch.cfg')
source=("retroarch-${pkgver}.tar.gz::https://github.com/libretro/RetroArch/archive/v${pkgver}.tar.gz"
'retroarch-config.patch'
'libre.patch')
sha256sums=('a60c2244609bb87cdb56dd8e1020c3be757569b5246141328804ebc5574327ea'
'14f07b31d6bdb049dad62dd12597c292b8d2df5cb2803d15de00a7597d3081fd'
'e8aa0c7a890c2e24012ecff4b7326bcf89214493ebf3138129aa7340585f3c62')
prepare() {
cd RetroArch-${pkgver}
patch -Np0 -i ../retroarch-config.patch
patch -Np1 -i ${srcdir}/libre.patch
}
build() {
cd RetroArch-${pkgver}
./configure \
--prefix='/usr' \
--disable-cg \
--disable-jack \
--disable-oss \
--disable-sdl
make
make -C libretro-common/audio/dsp_filters
make -C gfx/video_filters
}
package() {
cd RetroArch-${pkgver}
make DESTDIR="${pkgdir}" install
install -Dm 644 libretro-common/audio/dsp_filters/*.{dsp,so} -t "${pkgdir}"/usr/lib/retroarch/filters/audio/
install -Dm 644 gfx/video_filters/*.{filt,so} -t "${pkgdir}"/usr/lib/retroarch/filters/video/
}
# vim: ts=2 sw=2 et:
|
