blob: 93c1c4072d42d95d4b6e8082c56ab7d808434cbd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer (Arch):
# Contributor (Arch): Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve>
# Contributor (Arch): William Rea <sillywilly@gmail.com>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: fauno <fauno@kiwwwi.com.ar>
# Contributor: borgo <nomail>
# Contributor: André Silva <emulatorman@hyperbola.info>
_origname=reportlab
pkgbase=python-reportlab
pkgname=(python2-reportlab python-reportlab)
pkgver=3.5.12
pkgrel=1
pkgrel+=.par1
pkgdesc="A proven industry-strength PDF generating solution"
pkgdesc+=", without nonfree Adobe T1 fonts support"
arch=('x86_64')
arch+=('i686' 'armv7h')
url="https://bitbucket.org/rptlab/reportlab"
depends=('freetype2')
makedepends+=('python' 'python2' 'freetype2' 'python2-pillow' 'python-pillow' 'mercurial')
license=('custom')
source=(https://files.pythonhosted.org/packages/source/${_origname::1}/${_origname}/${_origname}-${pkgver}.tar.gz
'free-fonts.patch')
sha256sums=('7e10261065d0f926d9d83fd1f2edb8bec466f3c60b3e927ef40e2262805c069d'
'7e31b2a2bde509d628cb7da9fec301d730d38ea8a8dc9956cdfc8da4ebeec370')
prepare() {
cd "$srcdir/${_origname}-${pkgver}"
# remove nonfree Adobe T1 fonts support
patch -p1 -i ../free-fonts.patch
# Parabola contains those fonts from the ttf-bitstream-vera package
rm -fv src/reportlab/fonts/{bitstream-vera-license.txt,Vera*}
}
build() {
cp -rf ${_origname}-${pkgver} "${_origname}2"
}
package_python2-reportlab() {
depends+=('python2' 'python2-pip' 'python2-pillow')
cd ${_origname}2
python2 setup.py install --root=$pkgdir --optimize=1
install -D -m644 LICENSE.txt $pkgdir/usr/share/licenses/$pkgname/license.txt
}
package_python-reportlab() {
depends+=('python3' 'python-pip' 'python-pillow')
cd ${_origname}-${pkgver}
python3 setup.py install --root=$pkgdir --optimize=1
install -D -m644 LICENSE.txt $pkgdir/usr/share/licenses/$pkgname/license.txt
}
|
