blob: 2504818a65e5febc8600e1677979eb0191c8cb87 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
pkgname=parley
pkgver=17.12.1
pkgrel=1.parabola1
pkgdesc="Vocabulary Trainer, without qt5-webengine"
url="https://kde.org/applications/education/parley/"
arch=(x86_64)
license=(GPL LGPL FDL)
groups=(kde-applications kdeedu)
depends=(kross knewstuff libkeduvocdocument qt5-webkit kcmutils)
makedepends=(extra-cmake-modules kdoctools python)
replaces=(kdeedu-parley)
conflicts=(kdeedu-parley)
source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig}
"libre.patch")
sha256sums=('da2d3b6dcb7a858556a67c63957388b287c614ca5f290747f471b397359c38a5'
'SKIP'
'fa35b14d8c35cedf63685e5e9a8157dbc0bb5339c75a1356fb59359974c08e57')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7 # Albert Astals Cid <aacid@kde.org>
F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>
prepare() {
mkdir -p build
# remove qt5-webengine references
cd $pkgname-$pkgver
patch -Np1 -i "$srcdir"/libre.patch
}
build() {
cd build
cmake ../$pkgname-$pkgver \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr
make
}
package() {
cd build
make DESTDIR="$pkgdir" install
}
|
