blob: a77e12e441fe7e52d9dede4a8b8f831398b43ecc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer (Arch): Alexander F. Rødseth <xyproto@archlinux.org>
# Contributor (Arch): Andreas Radke <andyrtr@archlinux.org>
# Contributor (Arch): rabyte <rabyte@gmail.com>
# Contributor (Arch): Johannes Krampf <wuischke@amule.org>
# Contributor (Arch): Bartłomiej Piotrowski <barthalion@gmail.com>
# Contributor: André Silva <emulatorman@hyperbola.info>
pkgname=midori
pkgver=0.5.11
pkgrel=10
pkgrel+=.par1
pkgdesc='Lightweight web browser, without non-privacy search engines'
arch=('x86_64')
arch+=('i686' 'armv7h')
url='https://midori-browser.org/'
license=('LGPL')
depends=('aria2' 'gcr' 'gobject-introspection-runtime' 'libpeas' 'libxss' 'webkit2gtk' 'zeitgeist')
makedepends=('bzr' 'cmake' 'git' 'gobject-introspection' 'intltool' 'ninja' 'vala')
optdepends=('gst-plugins-base: HTML5 OGG videos support'
'gst-plugins-good: HTML5 H264 and WebM videos support'
'gst-libav: HTML5 H264 videos support')
options=('!emptydirs')
# The latest release of Midori does not build with GTK+ > 3.10.
# Using latest git commit while waiting for the next release.
source=("$pkgname::git+https://github.com/midori-browser/core.git#commit=7dab517e66475929336e80840cce2351891dd4ef")
md5sums=('SKIP')
# NOTE: Set GTK_CSD=1 for enabling client side decorations when running Midori
prepare() {
cd $pkgname
# Use DuckDuckGo HTML
sed -i 's|duckduckgo[.]com|duckduckgo.com/html|g' core/settings.vala
}
build() {
mkdir -p build
cd build
# TODO: Check if VALA_CFLAGS is respected
cmake "../$pkgname" \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=lib \
-DHALF_BRO_INCOM_WEBKIT2=ON \
-DCMAKE_C_FLAGS="$CFLAGS -fPIC -w" \
-DVALA_CFLAGS="$CFLAGS -fPIC -w" \
-G Ninja
ninja
}
package() {
DESTDIR="$pkgdir" ninja -C build install
}
# getver: -u 2 midori-browser.org/download/source
# vim:set ts=2 sw=2 et:
|
