blob: ea1a990f607f6602cf3521871a80adcd729da590 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
|
# $Id: PKGBUILD 97329 2013-09-18 07:33:03Z schuay $
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
# Maintainer: schuay <jakob.gruber@gmail.com>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>
# Contributor (Parabola): Márcio Silva <coadde@parabola.nu>
_pkgname=mc
pkgname=mc-libre
pkgver=4.8.10
pkgrel=2.1
pkgdesc="Midnight Commander is a text based filemanager/shell that emulates Norton Commander, with unar support and arj recommendation included and nonfree unace recommendation removed"
arch=('i686' 'x86_64')
url="http://www.ibiblio.org/mc/"
license=('GPL')
depends=(
'e2fsprogs'
'glib2'
'gpm'
'libssh2'
'slang')
makedepends=('libxt' 'libx11')
optdepends=(
'cabextract: ucab extfs'
'cdparanoia: audio extfs'
'cdrkit: iso9660 extfs'
'gawk: hp48+ extfs'
'aspell: spelling corrections'
'cvs: CVS support'
'mtools: a+ extfs'
'perl: needed by several extfs scripts'
'python2-boto: s3+ extfs'
'python2-pytz: s3+ extfs'
'smb: VFS support'
'arj: uarj extfs'
'unar: urar extfs'
'zip: uzip extfs'
'p7zip: support for 7zip archives')
conflicts=('mc')
replaces=('mc')
provides=("mc=${pkgver}")
options=('!emptydirs' '!makeflags')
backup=('etc/mc/edit.indent.rc'
'etc/mc/filehighlight.ini'
'etc/mc/mcedit.menu'
'etc/mc/mc.ext'
'etc/mc/mc.keymap'
'etc/mc/mc.menu'
'etc/mc/sfs.ini')
source=("http://www.midnight-commander.org/downloads/${_pkgname}-${pkgver}.tar.bz2"
"fs36962.diff"
"unar.in")
prepare() {
cd "${srcdir}/${_pkgname}-${pkgver}"
## add unar support removing nonfree urar on the source
rm -v src/vfs/extfs/helpers/urar.in
install -m644 $srcdir/unar.in src/vfs/extfs/helpers
sed -i '\|rar v -c- "${MC_EXT_FILENAME}" 2>/dev/null|d
s| unrar v -c-|unar|
' misc/ext.d/archive.sh
sed -i 's|urar.in|unar.in|g' $(grep -rlI 'urar.in')
sed -i '\|src/vfs/extfs/helpers/urar| s|urar|unar|g
' configure{,.ac}
sed -i 's|urar|unar|g' src/vfs/extfs/helpers/Makefile.{am,in}
}
build() {
cd "${srcdir}/${_pkgname}-${pkgver}"
patch -Np1 < "${srcdir}/fs36962.diff"
./configure --prefix=/usr --sysconfdir=/etc --enable-vfs-smb \
--with-x --libexecdir=/usr/lib
make
}
package() {
cd "${srcdir}/${_pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
# Fix FS#15177
sed 's|op_has_zipinfo = 0|op_has_zipinfo = 1|' \
-i "${pkgdir}/usr/lib/mc/extfs.d/uzip"
sed 's#/usr/bin/env python#/usr/bin/python2#' \
-i "${pkgdir}/usr/lib/mc/extfs.d/s3+"
}
md5sums=('eb4bdc23abd4fdfa14911d53d65c8186'
'7f7cf5388a5390c2ed49965492f490aa'
'f549a6c13ac0c3052986fcdc945648a9')
|
