blob: f342282d9168542a4f7b9c02c7b3bda16eda544a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Maintainer (arch): Antonio Rojas <arojas@archlinux.org>
# Maintainer (arch): Felix Yan <felixonmars@archlinux.org>
# Contributor (arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor (arch): Gustavo Alvarez <sl1pkn07@gmail.com>
# Contributor (arch): Balló György <ballogyor+arch at gmail dot com>
# Contributor: bill-auger <bill-auger@programmer.net>
# parabola changes and rationale:
# - replaced qt5-webengine dependency with qt5-webkit
pkgbase=marble
pkgname=(marble-common)
pkgver=20.12.1
pkgrel=2
pkgrel+=.parabola1
pkgdesc="Desktop Globe"
arch=(x86_64)
arch+=(armv7h i686)
url="https://www.kde.org/applications/system/marble"
license=(GPL)
makedepends=(extra-cmake-modules gpsd kdoctools knewstuff kparts krunner libwlocate phonon-qt5
plasma-workspace qt5-serialport qt5-tools qt5-webengine shapelib protobuf)
makedepends=(${makedepends[@]/qt5-webengine/qt5-webkit})
source=("https://download.kde.org/stable/release-service/$pkgver/src/$pkgbase-$pkgver.tar.xz"{,.sig})
sha256sums=('65c936ceefdd368494778e55a921f9d111e6fabab718b948f3f59ede5f446970'
'SKIP')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7 # Albert Astals Cid <aacid@kde.org>
F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>
build() {
cmake -B build -S $pkgbase-$pkgver \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_SYSCONFDIR=/etc \
-DQT_PLUGINS_DIR=lib/qt/plugins \
-DBUILD_TESTING=OFF \
-DBUILD_MARBLE_EXAMPLES=OFF \
-DBUILD_MARBLE_TESTS=OFF \
-DMOBILE=OFF
cmake --build build
}
package_marble-common() {
pkgdesc='Common libraries and plugins for Marble'
depends=(qt5-svg qt5-webengine phonon-qt5 protobuf)
depends=(${depends[@]/qt5-webengine/qt5-webkit})
optdepends=('gpsd: GPS based geolocation'
'libwlocate: WLAN based geolocation'
'qt5-serialport: APRS plugin'
'shapelib: SHP plugin')
DESTDIR="$pkgdir" cmake --install build
rm -r "$pkgdir"/usr/share/{config.kcfg,kxmlgui5,metainfo,plasma} \
"$pkgdir"/usr/bin \
"$pkgdir"/usr/share/knsrcfiles \
"$pkgdir"/usr/lib/qt/{qml,plugins/*.so} \
"$pkgdir"/usr/share/applications/{marble_geo.desktop,marble_worldwind.desktop,org.kde.marble*.desktop} \
"$pkgdir"/usr/share/kservices5/{marble_part.desktop,plasma*} \
"$pkgdir"/usr/share/locale/*/LC_MESSAGES/*.mo
}
|
