blob: 3534a93ea98aab3eb930bf16fbb34812373f7e64 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Maintainer: David P. <megver83@parabola.nu>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>
pkgname=linux-libre-firmware
pkgver=1.3
pkgrel=1
epoch=1
pkgdesc='Firmware files for Linux-libre'
arch=('any')
url='https://jxself.org/firmware'
license=('GPL3' 'GPL2')
makedepends=('arm-linux-gnueabi-gcc' 'arm-none-eabi-gcc' 'cmake' 'sh-elf-gcc' 'sh-elf-newlib' 'xtensa-elf-gcc')
provides=('linux-firmware')
conflicts=('linux-firmware'
'linux-firmware-git'
'kernel26-firmware'
'ar9170-fw'
'iwlwifi-1000-ucode'
'iwlwifi-3945-ucode'
'iwlwifi-4965-ucode'
'iwlwifi-5000-ucode'
'iwlwifi-5150-ucode'
'iwlwifi-6000-ucode'
'rt2870usb-fw'
'rt2x00-rt61-fw'
'rt2x00-rt71w-fw'
'amd-ucode'
'openfwwf'
'ath9k-htc-firmware')
replaces=(${conflicts[@]})
options=(!buildflags !makeflags)
source=("$url/$pkgname-$pkgver.tar.lz"{,.asc} 'remove-external-toolchains.patch')
sha512sums=('d3ead6924e686d0212c5993386fdf7ed1d2f68cb899517510ef488b2006a7bb9c1a8e511d23622e0342bdc70410c90291aad60adb2ac5db20c00b40a11508700'
'SKIP'
'2d45a7afd7e22bf558a24fa7777976ee6bbe5aa7c73b6fcccab32c28c52bb76de2647e5b8c1560bb6f9dd0e2e5c36befb1a776257c5f412437cdaa8f96290864')
validpgpkeys=('F611A908FFA165C699584ED49D0DB31B545A3198') # Jason Self
prepare() {
cd $srcdir/$pkgname-$pkgver
# do not download toolchains so we can build offline
patch -p0 -i ../remove-external-toolchains.patch
}
build() {
cd $srcdir/$pkgname-$pkgver
make -C src
}
package() {
cd $srcdir/$pkgname-$pkgver
install -dm755 $pkgdir/usr/lib/firmware
make -C src prefix=$pkgdir/usr/lib/firmware install
install -Dm644 src/WHENCE $pkgdir/usr/share/licenses/$pkgname/WHENCE
}
|
