blob: b2fa4b24cb95df930b25c0a5081fcf15e6973ae8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer (arch): Giancarlo Razzolini <grazzolini@archlinux.org>
# Maintainer (arch): Frederik Schwan <freswa at archlinux dot org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Allan McRae <allan@archlinux.org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: André Silva <emulatorman@hyperbola.info>
# toolchain build order: linux-api-headers->glibc->binutils->gcc->glibc->binutils->gcc
# parabola changes and rationale (based on core/linux-api-headers):
# - changing upstream source url to linux-libre
# - change arch from (any) to explicit list, since headers differ across arches
pkgname=linux-libre-api-headers
pkgver=5.17.3_gnu
_minor_ver=${pkgver%.*}
_upstream_ver=${pkgver//_/-}
_dep_ver=${pkgver%_*}
pkgrel=1
pkgdesc='Kernel headers sanitized for use in userspace'
arch=(x86_64 i686 armv7h)
url='https://www.gnu.org/software/libc'
license=(GPL2)
makedepends=(rsync)
provides=("linux-api-headers=${_dep_ver}")
source=(https://linux-libre.fsfla.org/pub/linux-libre/releases/${_minor_ver}-gnu/linux-libre-${_minor_ver}-gnu.tar.xz{,.sign}
https://linux-libre.fsfla.org/pub/linux-libre/releases/${_upstream_ver}/patch-${_minor_ver}-gnu-${_upstream_ver}.xz{,.sign})
sha256sums=('4e69f73df3c65132ef51500810bc3b08b069326355a9ea9471206e130c0c84a3'
'SKIP'
'e9cb3e778884431b94e8fa3b50db390adab594c67b29a6f36ff9b9b5f67e318a'
'SKIP')
validpgpkeys=('474402C8C582DAFBE389C427BCB7CF877E7D47A7') # Alexandre Oliva
prepare() {
cd linux-${_minor_ver}
patch -p1 -i "$srcdir/patch-${_minor_ver}-gnu-${_upstream_ver}"
}
build() {
cd linux-${_minor_ver}
make mrproper
}
package() {
cd linux-${_minor_ver}
make INSTALL_HDR_PATH="$pkgdir/usr" headers_install
# use headers from libdrm
rm -r "$pkgdir/usr/include/drm"
}
|
