libre/linux-libre-api-headers/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

# $Id$
# Maintainer (Arch):  Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor (Arch): Allan McRae <allan@archlinux.org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: André Silva <emulatorman@hyperbola.info>

# parabola changes and rationale (based on core/linux-api-headers):
#  - changing upstream source url to linux-libre

# toolchain build order: linux-api-headers->glibc->binutils->gcc->binutils->glibc

pkgname=linux-libre-api-headers
pkgver=4.15.2_gnu
_basever=${pkgver%.*_gnu}
pkgrel=1.1
pkgdesc='Kernel headers sanitized for use in userspace'
arch=(any)
url='http://www.gnu.org/software/libc'
license=(GPL2)
provides=("linux-api-headers=${pkgver%_*}")
conflicts=('linux-api-headers')
replaces=('linux-api-headers')
source=(https://linux-libre.fsfla.org/pub/linux-libre/releases/${_basever}-gnu/linux-libre-${_basever}-gnu.tar.xz{,.sign}
        https://linux-libre.fsfla.org/pub/linux-libre/releases/${pkgver//_/-}/patch-${_basever}-gnu-${pkgver//_/-}.xz{,.sign})
sha256sums=('e6556514286f9cd6b46f5d5769b2cc3c61ac7d6fa9c9c400e3c2fb5949490186'
            'SKIP'
            '81ec59f4d123f7b8bb358c765b4cae32979c6859816641f4830e6c87dc974875'
            'SKIP')
validpgpkeys=('474402C8C582DAFBE389C427BCB7CF877E7D47A7') # Alexandre Oliva

prepare() {
  cd linux-${_basever}
  [[ ${pkgver%_gnu} != $_basever ]] && patch -p1 -i "$srcdir/patch-${_basever}-gnu-${pkgver//_/-}"
}

build() {
  cd linux-${_basever}

  make mrproper
  make headers_check
}

package() {
  cd linux-${_basever}
  make INSTALL_HDR_PATH="$pkgdir/usr" headers_install

  # use headers from libdrm
  rm -r "$pkgdir/usr/include/drm"
  
  # clean-up unnecessary files generated during install
  find "$pkgdir" \( -name .install -o -name ..install.cmd \) -delete
}