blob: fd91bd1c278d206601921194c6c0af93b94b6c06 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
|
# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: Joshua Ismael Haase Hernández (xihh) <hahj87@gmail.com>
# Contributor: fauno <fauno@kiwwwi.com.ar>
# Contributor: Márcio Silva <coadde@parabola.nu>
pkgbase=libretools
pkgname=(libretools libretools-mips64el librelib gitget xbs)
pkgdesc="Programs for Parabola development"
url="https://projects.parabola.nu/packages/libretools.git/"
license=('GPL3' 'GPL2')
pkgver=20150104
_libretools_commit=a420c807d1b7ac3b5c5adbbb18ed99343ca5e6b6
_devtools_commit=5f4e575914fd597d31e5b9edd203eb6a8aa1306a
md5sums=('4ae548d11a768eceada91e2e4df96112'
'4fbe3aa6e7f87fa720547a8832d3419c')
_packages_url=https://projects.parabola.nu/packages
source=($_packages_url/libretools.git/snapshot/libretools-$_libretools_commit.tar.bz2
$_packages_url/devtools-par.git/snapshot/devtools-par-$_devtools_commit.tar.bz2)
pkgrel=1
arch=('any')
makedepends=(emacs ruby-ronn) # emacs --batch is used during the build to process text
checkdepends=(sh-roundup git)
build() {
cd "$srcdir"
ln -sf devtools-par-$_devtools_commit devtools-par
cd "$srcdir/$pkgbase-$_libretools_commit"
make build-libretools build-libretools-mips64el build-librelib build-doc
}
check() {
cd "$srcdir/$pkgbase-$_libretools_commit"
SUDO_USER= make check TESTENVFLAGS='--no-network --no-sudo'
}
package_librelib() {
pkgdesc="The shell library portion of libretools"
license=(GPL2)
depends=(
wget # `blacklist`
)
cd "$srcdir/$pkgbase-$_libretools_commit"
make install-librelib DESTDIR="$pkgdir"
}
package_gitget() {
pkgdesc="A simple to use downloader for git URLs"
license=(GPL2)
depends=("librelib=$pkgver" git)
provides=("libregit=$pkgver")
conflicts=("libregit")
replaces=("libregit")
cd "$srcdir/$pkgbase-$_libretools_commit"
make install-gitget DESTDIR="$pkgdir"
}
package_xbs() {
pkgdesc='A tool for working with arbitrary ABS-like build systems'
license=(GPL2)
depends=(
"gitget=$pkgver" # `helper-abslibre`
"librelib=$pkgver"
subversion # `helper-abs`
)
cd "$srcdir/$pkgbase-$_libretools_commit"
make install-xbs DESTDIR="$pkgdir"
}
package_libretools() {
backup=(etc/libretools.conf etc/libretools.d/chroot.conf etc/libretools.d/librefetch.conf)
install=libretools.install
conflicts=(devtools)
depends=(
"librelib=$pkgver"
"xbs=$pkgver" # `createworkdir`, `librestage`
'pacman>=4.2.0' 'pacman<4.3.0'
arch-install-scripts # `mkarchroot` uses `pacstrap`
openssh # `librerelease`
rsync # `librerelease` and `makechrootpkg.sh`
systemd # systemd-nspawn
tokyocabinet # `toru`
#namcap # Namcap is currently dissabled in libremakepkg :(
#subversion # `diff-unfree` # ignore because of xbs
#wget # `aur` # ignore because of librelib
)
cd "$srcdir/$pkgbase-$_libretools_commit"
make install-libretools install-doc DESTDIR="$pkgdir"
}
package_libretools-mips64el() {
pkgdesc="Scripts for Parabola development (for mips64el architecture)"
license=(GPL3)
depends=("$pkgbase=$pkgver"
git # mips-add
)
cd "$srcdir/$pkgbase-$_libretools_commit"
make install-libretools-mips64el DESTDIR="$pkgdir"
}
|
