1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# $Id: PKGBUILD 276436 2016-09-15 06:55:16Z arojas $
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>
pkgname=kio
pkgver=5.26.0
pkgrel=2.parabola1
pkgdesc='Resource and network access abstraction, without non-privacy search engines'
arch=('i686' 'x86_64')
url='https://community.kde.org/Frameworks'
license=('LGPL')
depends=('solid' 'kjobwidgets' 'kbookmarks' 'libxslt' 'kwallet' 'desktop-file-utils' 'kinit')
makedepends=('extra-cmake-modules' 'kdoctools' 'python')
optdepends=('kio-extras: extra protocols support (sftp, fish and more)')
groups=('kf5')
source=("http://download.kde.org/stable/frameworks/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz"
kio-konsole.patch::"https://quickgit.kde.org/?p=kio.git&a=commitdiff&h=c784a879&o=plain"
'duckduckgo_html.desktop'
'duckduckgo_lite.desktop')
md5sums=('c525ec050558e2d5c372616b8848aef8'
'eade65cf460457d7fd34085478f27b6d'
'59462f450ae72354ab3ca188710e2330'
'1ca9884d8dc89c5713a1f42033775bcd')
prepare() {
mkdir -p build
cd ${pkgname}-${pkgver}
# Removing non-privacy search providers
rm -v src/urifilters/ikws/searchproviders/{7digital,acronym,amazon{,_mp3},amg,backports,baidu,bing,blip,cia,dbug,deb,duckduckgo{,_info,_shopping},facebook,ecosia,feedster,flickr,flickrcc,google,google_advanced,google_code,google_groups,google_images,google_lucky,google_maps,google_movie,google_news,google_shopping,imdb,jamendo,jeeves,magnatune,metacrawler,msdn,nl-telephone,nl-teletekst,python,rpmfind,tvtome,uspto,vimeo,voila,yahoo,yahoo_image,yahoo_local,yahoo_shopping,yahoo_video,youtube}.desktop
# Adding DuckDuckGo HTML
cp -v "${srcdir}"/duckduckgo_html.desktop src/urifilters/ikws/searchproviders
# Adding DuckDuckGo Lite
cp -v "${srcdir}"/duckduckgo_lite.desktop src/urifilters/ikws/searchproviders
# Fix launching terminal applications
patch -p1 -i ../kio-konsole.patch
}
build() {
cd build
cmake ../${pkgname}-${pkgver} \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DKDE_INSTALL_LIBDIR=lib \
-DKDE_INSTALL_LIBEXECDIR=lib \
-DBUILD_TESTING=OFF
make
}
package() {
cd build
make DESTDIR="${pkgdir}" install
}
|
