blob: 50b8c2b7cc44cc7f6483f0f482ee7ab4ee599602 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# $Id: PKGBUILD 236016 2015-04-10 06:56:26Z arojas $
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>
pkgname=kdeutils-ark
pkgver=15.04.0
pkgrel=1.parabola1
pkgdesc='Archiving Tool, with unar support'
url='http://kde.org/applications/utilities/ark/'
arch=('i686' 'x86_64' 'mips64el')
license=('GPL' 'LGPL' 'FDL')
groups=('kde-applications' 'kdeutils')
replaces=('kdeutils-ark-libre')
conflicts=('kdeutils-ark-libre')
depends=('kdebase-runtime' 'kdebase-lib' 'libarchive' 'qjson')
makedepends=('cmake' 'automoc4')
optdepends=('p7zip' 'zip' 'unzip' 'unar')
install=${pkgname}.install
source=("http://download.kde.org/stable/applications/${pkgver}/src/ark-${pkgver}.tar.xz"
'ark-unar-06.patch')
sha1sums=('7f5d5bd32ab472e2c17f51d9ee19d16cdb9c9fbe'
'a0a836950f185d9b2245204579f969203036fdec')
prepare() {
cd "${srcdir}/ark-${pkgver}"
# This patch will allow Ark to use The Unarchiver command line utilities (unar/lsar) to operate on RAR files, particularly RARv3.
patch -Np1 -i "${srcdir}/ark-unar-06.patch"
}
build() {
cd "${srcdir}"
mkdir build
cd build
cmake ../ark-${pkgver} \
-DCMAKE_BUILD_TYPE=Release \
-DKDE4_BUILD_TESTS=OFF \
-DCMAKE_INSTALL_PREFIX=/usr
make
}
package() {
cd $srcdir/build
make DESTDIR=$pkgdir install
}
|
