blob: a4122737d18386a3895439ea108861168dcf72a2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>
pkgname=kdepim-addons
pkgver=17.08.3
pkgrel=1.parabola1
arch=(i686 x86_64 armv7h)
pkgdesc="Addons for KDE PIM applications (built without nonfree qt5-webengine)"
url="https://community.kde.org/KDE_PIM"
license=(GPL LGPL FDL)
depends=(incidenceeditor libktnef libksieve akonadi-notes akonadi-import-wizard)
makedepends=(extra-cmake-modules kdoctools boost python kdesignerplugin)
groups=(kde-applications kdepim)
source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig}
'libre.patch')
sha256sums=('9d3c674320b311f5107dd6292760a74ceab84107800e23df16e8091e697e18e4'
'SKIP'
'6a8dafaedbdc3c5f19fd2b59459b54c25e0df35e5c6602f49ef75a7e5dbf2bf6')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7 # Albert Astals Cid <aacid@kde.org>
F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>
prepare() {
mkdir -p build
cd $pkgname-$pkgver
patch -p1 -i ../libre.patch
rm -rv plugins/webengineurlinterceptor
}
build() {
cd build
cmake ../$pkgname-$pkgver \
-DCMAKE_BUILD_TYPE=Release \
-DBUILD_TESTING=OFF \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=lib
make
}
package() {
cd build
make DESTDIR="$pkgdir" install
}
|
