1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
|
# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor (Arch): Pierre Schmitz <pierre@archlinux.de>
pkgname=kdebase-runtime
pkgver=17.08.3
pkgrel=1.parabola1
arch=(i686 x86_64 armv7h)
pkgdesc="Plugins and applications necessary for the running of KDE applications, without non-privacy search engines"
url="https://www.kde.org/"
license=(GPL LGPL)
makedepends=(pkg-config cmake automoc4 openslp doxygen networkmanager boost)
depends=(kdelibs smbclient libssh libcanberra oxygen-icons xorg-xauth libwebp exiv2 gpgme)
optdepends=('drkonqi: crash report tool'
'khelpcenter: to display applications documentation')
provides=(notification-daemon)
conflicts=(kdesu4)
replaces=(kdesu4)
source=("https://download.kde.org/stable/applications/${pkgver}/src/kde-runtime-${pkgver}.tar.xz"{,.sig}
'duckduckgo_html.desktop'
'duckduckgo_lite.desktop'
'kdebase-runtime-no-html-thumbnails.patch'
'kdebase-runtime-no-kdewebkit.patch')
sha256sums=('682c18afb11cda41288c4508831cb59797417b9d81ea916e0e99722ebe9bce96'
'SKIP'
'31910ab7393e67609f15e04a57f6406f63e6dae58b01bce0787741bc5958f292'
'40466a9dad7075f2525e9e024720da7d7b49a22892b6fca8b81cc0e6408d2f7d'
'5ce434f25759215ed2b6f71ec82a9118ee76e7428ef1af8a5495133a76c9c2df'
'93d5ddf78c784b3d79486813bdfb43debba271b389bfc46ca79aabdb0bca14db')
validpgpkeys=('CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7' # Albert Astals Cid <aacid@kde.org>
'F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87') # Christoph Feck <cfeck@kde.org>
prepare() {
mkdir -p build
cd kde-runtime-${pkgver}
# Don't link to kactivities
sed -e '/plasmaextracomponents/d' -i plasma/declarativeimports/CMakeLists.txt
# Drop HTML thumbnailer, uses insecure QtWebKit
patch -p1 -i ../kdebase-runtime-no-html-thumbnails.patch
patch -p1 -i ../kdebase-runtime-no-kdewebkit.patch
# Removing non-privacy search providers
rm -v kurifilter-plugins/ikws/searchproviders/{7digital,acronym,amazon{,_mp3},amg,backports,baidu,bing,blip,cia,dbug,deb,duckduckgo{,_info,_shopping},facebook,ecosia,feedster,flickr,flickrcc,google,google_advanced,google_code,google_groups,google_images,google_lucky,google_maps,google_movie,google_news,google_shopping,imdb,jamendo,jeeves,magnatune,metacrawler,msdn,nl-telephone,nl-teletekst,python,rpmfind,tvtome,uspto,vimeo,voila,yahoo,yahoo_image,yahoo_local,yahoo_shopping,yahoo_video,youtube}.desktop
# Adding DuckDuckGo HTML
cp -v "${srcdir}"/duckduckgo_html.desktop kurifilter-plugins/ikws/searchproviders
# Adding DuckDuckGo Lite
cp -v "${srcdir}"/duckduckgo_lite.desktop kurifilter-plugins/ikws/searchproviders
}
build() {
cd build
cmake ../kde-runtime-$pkgver \
-DCMAKE_BUILD_TYPE=Release \
-DKDE4_BUILD_TESTS=OFF \
-DCMAKE_SKIP_RPATH=ON \
-DCMAKE_INSTALL_PREFIX=/usr \
-DWITH_QNtrack=OFF \
-DSAMBA_INCLUDE_DIR=/usr/include/samba-4.0 \
-DWITH_NepomukCore=OFF \
-DBUILD_khelpcenter=OFF \
-DBUILD_kglobalaccel=OFF \
-DBUILD_kuiserver=OFF \
-DBUILD_drkonqi=OFF \
-DBUILD_doc=OFF
make
}
package() {
cd build
make DESTDIR="$pkgdir" install
rm "$pkgdir"/usr/share/icons/hicolor/index.theme
ln -s /usr/lib/kde4/libexec/kdesu "$pkgdir"/usr/bin/kdesu4
# Use KF5 drkonqi
ln -s /usr/lib/drkonqi "$pkgdir"/usr/lib/kde4/libexec/
# FS#36668
chown :nobody "$pkgdir"/usr/lib/kde4/libexec/kdesud
chmod g+s "$pkgdir"/usr/lib/kde4/libexec/kdesud
}
|
