blob: 49f361b31404f5571eb7df53cbdd97c12dbc0b58 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
_libname=xmlgraphics-commons
pkgname=java-${_libname}
pkgver=1.5
pkgrel=2.parabola1
pkgdesc="Common components between FOP and Batik."
arch=('any')
url="http://xmlgraphics.apache.org/commons/"
license=('APACHE')
depends=('java-runtime')
makedepends=('java-commons-io' 'java-commons-logging' 'java-environment' 'jh')
source=("https://archive.apache.org/dist/xmlgraphics/commons/source/${_libname}-${pkgver}-src.tar.gz"
"https://repo1.maven.org/maven2/org/apache/xmlgraphics/${_libname}/${pkgver}/${_libname}-${pkgver}.pom")
md5sums=('e7012400a3c9d10a18bc5c3515610f35'
'feb55c9c61fa0b63f2926ad8872bc2a5')
prepare() {
cd "${srcdir}/${_libname}-${pkgver}"
rm -v $(find . -name \*.jar)
mkdir -p build/classes
}
build() {
cd "${srcdir}/${_libname}-${pkgver}"
CLASSPATH="/usr/share/java/commons-io.jar:/usr/share/java/commons-logging.jar"
javac -encoding UTF-8 -classpath $CLASSPATH -d "build/classes" \
$(find "src/java" -name \*.java)
javadoc -encoding UTF-8 -classpath $CLASSPATH -d "build/javadoc" \
-sourcepath "src/java" -subpackages org
jar -cvf "${_libname}.jar" -C "build/classes" .
}
package() {
cd "${srcdir}/${_libname}-${pkgver}"
# Install documentation
install -d "${pkgdir}/usr/share/doc/${pkgname}"
cp -r "build/javadoc" "${pkgdir}/usr/share/doc/${pkgname}"
cp -r "examples/java" "${pkgdir}/usr/share/doc/${pkgname}/examples"
# Install Maven artifacts
export DESTDIR=${pkgdir}
jh mvn-install "org.apache.xmlgraphics" ${_libname} ${pkgver} \
"${srcdir}/${_libname}-${pkgver}.pom" \
"${_libname}.jar" \
"${_libname}.jar"
ln -s "/usr/share/java/${_libname}.jar" \
"${pkgdir}/usr/share/java/${_libname}-${pkgver}.jar"
install -d "${pkgdir}/usr/share/java/${_libname}"
ln -s "/usr/share/java/${_libname}.jar" \
"${pkgdir}/usr/share/java/${_libname}/${_libname}.jar"
}
|
