blob: 96511080315d7ccafbd6cdccf7076e12456a05b7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Maintainer (arch): Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Isaac David <isacdaavid@at@isacdaavid@dot@info>
# Contributor: Iván Ávalos <avalos@disroot.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# parabola changes and rationale:
# - rebranded to parabola
# - switched default searchengine to duckduckgo
# - removed useless dependency on icu because it's not
# used at runtime according to readelf -d
# - pin to sodeps
pkgname=epiphany
pkgver=42.3
pkgrel=1
pkgrel+=.parabola1
pkgdesc="A GNOME web browser based on the WebKit rendering engine"
pkgdesc+=", with DuckDuckGo-HTML search"
url="https://wiki.gnome.org/Apps/Web"
arch=(x86_64)
arch+=(i686 armv7h)
license=(GPL)
depends=(webkit2gtk-4.1 gcr icu libdazzle libhandy libarchive libportal-gtk3)
depends=( $( sed 's| icu | |' <<<${depends[@]} ) )
depends+=(libhogweed.so)
makedepends=(docbook-xml startup-notification lsb-release gobject-introspection
yelp-tools git meson)
checkdepends=(xorg-server-xvfb aspell hspell hunspell nuspell libvoikko)
groups=(gnome)
_commit=6cdf86702e747867b2f4b338429733f84f554f80 # tags/42.3^0
source=("git+https://gitlab.gnome.org/GNOME/epiphany.git#commit=$_commit")
source+=(libre.patch)
sha256sums=('SKIP')
sha256sums+=('bf1dd1692ec9f94f8fc669a5ee71dd811d6083465dbb197e3fcc64e2aaf2f709')
# check() requires networking
_run_check=0
pkgver() {
cd $pkgname
git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
}
prepare() {
cd $pkgname
echo "applying libre.patch"
patch -Np1 -i ../libre.patch
}
build() {
arch-meson $pkgname build -D soup2=disabled
meson compile -C build
}
check() {
(( _run_check )) || ! echo "skipping check()" || return 0
dbus-run-session xvfb-run -s '-nolisten local' \
meson test -C build --print-errorlogs
}
package() {
meson install -C build --destdir "$pkgdir"
}
|
