blob: 61670baf28bb488dcdc6b76baab3519627aef7dc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# $Id$
# Maintainer (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Isaac David <isacdaavid@at@isacdaavid@dot@info>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# parabola changes and rationale:
# - rebranded to parabola
# - switched default searchengine to duckduckgo
pkgname=epiphany
pkgver=3.28.3.1
pkgrel=1.parabola1
pkgdesc="A GNOME web browser based on the WebKit rendering engine, with DuckDuckGo HTML support"
url="https://wiki.gnome.org/Apps/Web"
arch=(x86_64 i686 armv7h)
license=(GPL)
depends=(webkit2gtk gcr icu)
makedepends=(itstool docbook-xml startup-notification lsb-release
gobject-introspection yelp-tools appstream-glib git meson)
groups=(gnome)
_commit=a5a9a7e2904e2206b3cc863ab13748255247e3eb # tags/3.28.3.1^0
source=("git+https://gitlab.gnome.org/GNOME/epiphany.git#commit=$_commit"
pluginsdir.diff
libre.patch)
sha256sums=('SKIP'
'b6c8ee6ace934c053f2fd89758e0b587cb8953c6b0246c1359aecaae4de70289'
'8cee8e5f896ce12832d50e7ab97ef16165d70d135018742e0f5bc15507d4e708')
pkgver() {
cd $pkgname
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd $pkgname
patch -Np1 -i ../pluginsdir.diff
patch -Np1 -i ../libre.patch
}
build() {
arch-meson $pkgname build \
-D distributor_name="Parabola GNU/Linux-libre"
ninja -C build
}
package() {
DESTDIR="$pkgdir" ninja -C build install
}
|
