blob: a7bf5ffdb284a9d441218c201873a58146486021 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Contributor (Arch): Martin Wimpress <code@flexion.org>
# Maintainer (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
pkgname=engrampa
pkgver=1.20.0
pkgrel=1.parabola1
pkgdesc="Archive manipulator for MATE, without nonfree unace and unrar recommendation"
url="https://mate-desktop.org"
arch=('i686' 'x86_64' 'armv7h')
license=('GPL')
depends=('gtk3' 'gzip' 'libarchive' 'tar' 'unzip' 'zip')
makedepends=('caja' 'intltool' 'itstool' 'python')
optdepends=('caja: file archiver extension'
'p7zip: 7Z and ARJ archive support')
groups=('mate-extra')
conflicts=("engrampa-gtk3")
replaces=("engrampa-gtk3")
source=("https://pub.mate-desktop.org/releases/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz"
fr-rpm-bsdtar.patch)
sha256sums=('d5daac72a67a5e5b3d317f0031cc59e63c89c9b5fcc689932e192812e22860de'
'dc05c3b3fbc8242d1c85b58f756f998d644d920c8444d0872e9ffef1ce297f77')
prepare() {
cd ${pkgname}-${pkgver}
# This patch 'depends' on libarchive
patch -Np1 -i "${srcdir}/fr-rpm-bsdtar.patch"
}
build() {
cd ${pkgname}-${pkgver}
./configure \
--prefix=/usr \
--libexecdir=/usr/lib/${pkgname} \
--disable-packagekit
#https://bugzilla.gnome.org/show_bug.cgi?id=656231
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd ${pkgname}-${pkgver}
make DESTDIR="${pkgdir}" install
}
|
